Jam13Yuuka/game/script.rpy

# What is left?
#                 TEXT    STAGE    VAR
# introduction      Y       Y       Y
# icebreakers       Y       Y       Y
# hands-on lecture  Y       N       Y
# consultation      Y       N       Y
# exam              Y       Y       Y
# side convos       Y       Y       Y
# sunflower talk    Y       Y       Y
# present. endings  N       N       N

default persistent.pixelfont = True
default persistent.laozi = False
default persistent.playeranswer1 = ""
default persistent.playeranswer2 = ""
default persistent.playeranswer3 = ""
default persistent.playeranswer4 = ""
default persistent.playeranswer5 = ""
default persistent.officialrun = object
default persistent.dontsavefutureruns = False

define yuuka = Character("Yuuka", callback = name_callback, cb_name = "yuuka")
define reimu = Character("Reimu", callback = name_callback, cb_name = "reimu")
define marisa = Character("Marisa", callback = name_callback, cb_name = "marisa")
define alice = Character("Alice", callback = name_callback, cb_name = "alice")
define yumemi = Character("Yumemi", callback = name_callback, cb_name = "yumemi")
define janitor = Character("Totally Normal Janitor", callback = name_callback, cb_name = "yumemi")
define narrator = Character(callback = name_callback, cb_name = None)

init python:
    def truncate(n, decimals=0):
        multiplier = 10 ** decimals
        return int(n * multiplier) / multiplier

# Special player menus #
screen time_travel_display_toggle:
    zorder 200
    frame:
        background "#000000cc"
        xalign 0.05
        yalign 0.0

        textbutton "PSH":
            action ToggleScreen("time_travel_device")

    on "hide" action Hide("inventory_item_description")

screen time_travel_device:
    modal True
    window:
        background "#000000cc"
        xsize 800
        ysize 150
        xalign 0.5
        yalign 0.1
        text "To when, will Yuuka go?":
            xfill True
            yfill True
    
    window:
        background "#000000cc"
        xsize 1250
        ysize 450
        xalign 0.5
        yalign 0.5
        vbox:
            box_wrap True
            box_wrap_spacing 10
            spacing 10
            xoffset 20
            textbutton "After First Lecture":
                action Jump("TT_FirstLecture")
            textbutton "After Consultations":
                action Jump("TT_Consultations")
            textbutton "After Exam Day":
                action Jump("TT_ExamDay")
            textbutton "After Final Presentation":
                action Jump("TT_FinalPresentation")


    on "hide" action SetVariable("item_description", "")

define longfade = Fade(0, 0.5, 3)

# Camera flash - quickly fades to white, then back to the scene.
define flash = Fade(0.1, 0.0, 0.5, color="#fff")

define longflash = Fade(0.1, 1, 1, color="#fff")


label TT_FirstLecture:
    stop music
    stop sound
    play sound "teleport.opus"
    scene bg black with fade
    scene bg hallway with longflash
    play sound "teleport.opus"
    $ day = 1
    $ time_traveling = True
    $ renpy.pause(4.0)
    if(first_time_traveling_through_time):
        yuuka "Woah! Fuck."

        yuuka "This thing really works? Huh."

        yuuka "..."
        $ first_time_traveling_through_time = False
    jump hallway
    return

label TT_Consultations:
    stop music
    stop sound
    play sound "teleport.opus"
    scene bg black with fade
    scene bg hallway with longflash
    play sound "teleport.opus"
    $ day = 2
    $ time_traveling = True
    $ renpy.pause(4.0)
    if(first_time_traveling_through_time):
        yuuka "Woah! Fuck."

        yuuka "This thing really works? Huh."

        yuuka "..."
        $ first_time_traveling_through_time = False
    jump hallway
    return

label TT_ExamDay:
    stop music
    stop sound
    play sound "teleport.opus"
    scene bg black with fade
    scene bg hallway with longflash
    play sound "teleport.opus"
    $ day = 3
    $ time_traveling = True
    $ renpy.pause(4.0)
    if(first_time_traveling_through_time):
        yuuka "Woah! Fuck."

        yuuka "This thing really works? Huh."

        yuuka "..."
        $ first_time_traveling_through_time = False
    jump hallway
    return

label TT_FinalPresentation:
    stop music
    stop sound
    play sound "teleport.opus"
    scene bg black with fade
    scene bg hallway with longflash
    play sound "teleport.opus"
    $ day = 4
    $ time_traveling = True
    $ renpy.pause(4.0)
    if(time_travel_without_choice):
        yuuka "Hold, hold, hold on I."

        yuuka "What?"

        yuuka "Okay, okay. I think I've gotten a hold of myself."

        yuuka "I'm not sure if I can keep track of what's happened and what hasn't so this is going to be... confusing."

        yuuka "But I think I remember enough."
        $ time_travel_without_choice = False
    jump hallway
    return

# inventory system taken from a deranged reddit post
# https://www.reddit.com/r/RenPy/comments/wanes3/how_to_do_an_inventory_system/ii2vp6i/
screen inventory_display_toggle:
    zorder 200
    frame:
        background "#000000cc"
        xalign 0.0
        yalign 0.0

        textbutton "INV":
            action ToggleScreen("inventory_item_description")

    on "hide" action Hide("inventory_item_description")

# inventory item descriptions

default item_descriptions = {"Strange Device" : "Keychain-sized, has the initials PSH, has an Outside World look to it.", "Keycard" : "Given by that stranger I never got a look at...", "Clue #1" : "Yumemi's doing something on a different order of magnitude than before.","Clue #2" : "The passcode is likely to do with an important day, month, or year like a birthday.", "Clue #3" : "Yumemi's fond of symmetry, possibly ambigrams.", "Clue #4" : "01101101 01100101 01100100 01101001 01110101 01101101 00100000 01101001 01110011 00100000 01101101 01110011 01100111"}
default inventory_items = []
default item_description = ""

init python:
    def GetItemDescription(item):
        if item in item_descriptions:
            return item_descriptions.get(item)
        else:
            return item_description

# style inv_button is frame:
#     xsize 200
#     ysize 100

style inv_button_text:
    xalign 0.5
    yalign 0.5

screen inventory_item_description:
    # use this based on your preference
    modal True
    window:
        background "#000000cc"
        xsize 1100
        ysize 300
        xalign 0.5
        yalign 0.05
        text item_description:
            xfill True
            yfill True

    window:
        background "#000000cc"
        xsize 1290
        ysize 600
        xalign 0.5
        yalign 0.8
        hbox:
            box_wrap True
            box_wrap_spacing 10
            spacing 10
            xoffset 20
            yoffset 20
            style_prefix "inv"
            for item in inventory_items:
                textbutton item:
                    action SetVariable("item_description", GetItemDescription(item))
                    selected False


    on "hide" action SetVariable("item_description", "")
    
label splashscreen:
    scene black

    python:
        import time

        if persistent.secretKey is None:
            persistent.secretKey = truncate(time.time() * 666, 12)

            renpy.save_persistent()

    show text "Hit Shift-A to replace the font and change text scaling."
    with Pause(7)

    hide text with fade
    $ renpy.pause(1.0)

    show text "This is a fan-made video game not affiliated\nwith or endorsed by the original creators.\n\n{color=e63d3c}Touhou Project{/color} original concept, characters, and elements are property of {color=e63d3c}ZUN{/color} and {color=e63d3c}Team Shanghai Alice{/color}. Please support the official series."
    with Pause(7)

    hide text with fade
    $ renpy.pause(1.0)

    nvl clear

    return

transform damaged:
    yalign 0.5
    xalign 0.5
    ease .08 xoffset 40
    ease .08 xoffset -40
    ease .07 xoffset 30
    ease .07 xoffset -30
    ease .06 xoffset 20
    ease .06 xoffset -20
    ease .05 xoffset 15
    ease .05 xoffset -15
    ease .04 xoffset 10
    ease .04 xoffset -10
    ease .03 xoffset 5
    ease .03 xoffset -5
    ease .02 xoffset 2
    ease .02 xoffset -2
    ease .01 xoffset 0

transform thrown_offscreen:
    ease .5 xoffset 100 yoffset -100
    ease .4 xoffset 200 yoffset -200
    ease .3 xoffset 400 yoffset -400
    ease .3 xoffset 800 yoffset -800
    ease .2 xoffset 1600 yoffset -1600
    ease .2 xoffset 3200 yoffset -3200
    ease .1 xoffset 6400 yoffset -6400

transform flip:
    xzoom -1.0

transform unflip:
    xzoom 1.0

transform idle_vertical:
    yoffset 0
    ease 0.06
    yoffset 1
    ease 0.08
    yoffset 2
    ease 0.10
    yoffset 3
    ease 0.12
    yoffset 4
    ease 0.14
    yoffset 5
    ease 0.16
    yoffset 6
    ease 0.18
    yoffset 7
    ease 0.20
    yoffset 8
    ease 0.22
    yoffset 9
    ease 0.48
    yoffset 10
    ease 0.22
    yoffset 9
    ease 0.20
    yoffset 8
    ease 0.18
    yoffset 7
    ease 0.16
    yoffset 6
    ease 0.14
    yoffset 5
    ease 0.12
    yoffset 4
    ease 0.10
    yoffset 3
    ease 0.08
    yoffset 2
    ease 0.06
    yoffset 1
    ease 0.04
    repeat

transform idle_horizontal:
    xoffset 0
    ease 0.06
    xoffset 1
    ease 0.08
    xoffset 2
    ease 0.10
    xoffset 3
    ease 0.12
    xoffset 4
    ease 0.14
    xoffset 5
    ease 0.16
    xoffset 6
    ease 0.18
    xoffset 7
    ease 0.20
    xoffset 8
    ease 0.22
    xoffset 9
    ease 0.48
    xoffset 10
    ease 0.22
    xoffset 9
    ease 0.20
    xoffset 8
    ease 0.18
    xoffset 7
    ease 0.16
    xoffset 6
    ease 0.14
    xoffset 5
    ease 0.12
    xoffset 4
    ease 0.10
    xoffset 3
    ease 0.08
    xoffset 2
    ease 0.06
    xoffset 1
    ease 0.04
    repeat

transform spin:
    around (.5, .5)
    alignaround (.5, .5) xalign .5 yalign .5
    rotate 0
    linear 1 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.75 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.5 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.25 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

    around (.5, .5)
    alignaround (.5, .5)
    rotate 0
    linear 0.125 rotate 360

image yuuka amused:
    "yuuka amused.png"
    function SpriteFocus('yuuka')

image yuuka happy:
    "yuuka happy.png"
    function SpriteFocus('yuuka')

image yuuka irritated:
    "yuuka irritated.png"
    function SpriteFocus('yuuka')

image yuuka looking eyes:
    "yuuka looking eyes.png"
    function SpriteFocus('yuuka')

image yuuka looking:
    "yuuka looking.png"
    function SpriteFocus('yuuka')

image yuuka neutral:
    "yuuka neutral.png"
    function SpriteFocus('yuuka')

image yuuka rage:
    "yuuka rage.png"
    function SpriteFocus('yuuka')

image reimu angry:
    "reimu angry.png"
    function SpriteFocus('reimu')

image reimu concerned:
    "reimu concerned.png"
    function SpriteFocus('reimu')

image reimu happy:
    "reimu happy.png"
    function SpriteFocus('reimu')

image reimu neutral:
    "reimu neutral.png"
    function SpriteFocus('reimu')

image reimu serious:
    "reimu serious.png"
    function SpriteFocus('reimu')

image reimu sleepy:
    "reimu sleepy.png"
    function SpriteFocus('reimu')

image reimu surprise:
    "reimu surprise.png"
    function SpriteFocus('reimu')

image yumemi disguise:
    "yumemi disguise.png"
    function SpriteFocus('yumemi')

image yumemi glasses:
    "yumemi glasses.png"
    function SpriteFocus('yumemi')

image yumemi happy:
    "yumemi happy.png"
    function SpriteFocus('yumemi')

image yumemi neutral:
    "yumemi neutral.png"
    function SpriteFocus('yumemi')

image yumemi serious:
    "yumemi serious.png"
    function SpriteFocus('yumemi')

image yumemi wistful:
    "yumemi wistful.png"
    function SpriteFocus('yumemi')

image marisa concerned:
    "marisa concerned.png"
    function SpriteFocus('marisa')

image marisa defiant:
    "marisa defiant.png"
    function SpriteFocus('marisa')

image marisa happy:
    "marisa happy.png"
    function SpriteFocus('marisa')

image marisa laugh:
    "marisa laugh.png"
    function SpriteFocus('marisa')

image marisa neutral:
    "marisa neutral.png"
    function SpriteFocus('marisa')

image marisa serious:
    "marisa serious.png"
    function SpriteFocus('marisa')

image marisa surprise:
    "marisa surprise.png"
    function SpriteFocus('marisa')

image alice angry:
    "alice angry.png"
    function SpriteFocus('alice')

image alice happy:
    "alice happy.png"
    function SpriteFocus('alice')

image alice neutral:
    "alice neutral.png"
    function SpriteFocus('alice')

image alice surprise:
    "alice surprise.png"
    function SpriteFocus('alice')

image alice worried:
    "alice worried.png"
    function SpriteFocus('alice')

screen devModeButtons1():
    grid 3 12:
        $ i = 0
        for labelName in sorted(list(renpy.get_all_labels()))[:36]:
            textbutton labelName action Jump(labelName)
            $ i += 1
    hbox:
        spacing 20
        xpos 0
        ypos 950
        textbutton "(1*)":
            action Jump("DevModePage1")
        textbutton "(2)":
            action Jump("DevModePage2")
        textbutton "(3)":
            action Jump("DevModePage3")
        textbutton "(H)":
            action Jump("DevModeHide")
        textbutton "+D":
            action Jump("IncreaseDay")
        textbutton "-D":
            action Jump("DecreaseDay")

screen devModeButtons2():
    grid 3 12:
        $ i = 0
        for labelName in sorted(list(renpy.get_all_labels()))[36:72]:
            textbutton labelName action Jump(labelName)
            $ i += 1
    hbox:
        spacing 20
        xpos 0
        ypos 950
        textbutton "(1)":
            action Jump("DevModePage1")
        textbutton "(2*)":
            action Jump("DevModePage2")
        textbutton "(3)":
            action Jump("DevModePage3")
        textbutton "(H)":
            action Jump("DevModeHide")
        textbutton "+D":
            action Jump("IncreaseDay")
        textbutton "-D":
            action Jump("DecreaseDay")

screen devModeButtons3():
    grid 3 12:
        $ i = 0
        for labelName in sorted(list(renpy.get_all_labels()))[72:]:
            textbutton labelName action Jump(labelName)
            $ i += 1
    hbox:
        spacing 20
        xpos 0
        ypos 950
        textbutton "(1)":
            action Jump("DevModePage1")
        textbutton "(2)":
            action Jump("DevModePage2")
        textbutton "(3*)":
            action Jump("DevModePage3")
        textbutton "(H)":
            action Jump("DevModeHide")
        textbutton "+D":
            action Jump("IncreaseDay")
        textbutton "-D":
            action Jump("DecreaseDay")

screen devModeButtons4():
    hbox:
        spacing 20
        xpos 0
        ypos 950
        textbutton "(1)":
            action Jump("DevModePage1")
        textbutton "(2)":
            action Jump("DevModePage2")
        textbutton "(3)":
            action Jump("DevModePage3")
        textbutton "(H*)":
            action Jump("DevModeHide")
        textbutton "+D":
            action Jump("IncreaseDay")
        textbutton "-D":
            action Jump("DecreaseDay")

init python:
    # 0 means intro
    # 1 means icebreaker onwards
    # 2 means hands-on lecture onwards
    # 3 means consultation onwards
    # 4 means exam onwards
    day = 0
    next_label = ""

    # CHOICE VARIABLES #
    attacked_student = False
    garden_of_the_sun_lecture = False
    janitor_talks = 0
    revolution = 0 # 1 means students incited, 2 means students and teachers incited
    exam_cancelled = False
    investigation_progress = 0
    reimu_progress = 0
    alice_progress = 0
    marisa_progress = 0
    time_traveling = False
    asked_office_location = False
    did_not_submit_passcode = False
    has_correct_passcode = False
    chose_reimu_question = False
    first_time_traveling_through_time = True
    time_travel_without_choice = True
    aliceClue = False
    reimuClue = False
    marisaClue = False
    binaryClue = False

    class RunSave:
        def __init__(self, attacked_student, garden_of_the_sun_lecture, janitor_talks, revolution, exam_cancelled, investigation_progress, reimu_progress, alice_progress, marisa_progress, time_traveling, asked_office_location, did_not_submit_passcode, has_correct_passcode, chose_reimu_question, first_time_traveling_through_time, time_travel_without_choice, aliceClue, reimuClue, marisaClue, binaryClue, inventory_items):
            self.attacked_student = attacked_student
            self.garden_of_the_sun_lecture = garden_of_the_sun_lecture
            self.janitor_talks = janitor_talks
            self.revolution = revolution
            self.exam_cancelled = exam_cancelled
            self.investigation_progress = investigation_progress
            self.reimu_progress = reimu_progress
            self.alice_progress = alice_progress
            self.marisa_progress = marisa_progress
            self.time_traveling = time_traveling
            self.asked_office_location = asked_office_location
            self.did_not_submit_passcode = did_not_submit_passcode
            self.has_correct_passcode = has_correct_passcode
            self.chose_reimu_question = chose_reimu_question
            self.first_time_traveling_through_time = first_time_traveling_through_time
            self.time_travel_without_choice = time_travel_without_choice
            self.aliceClue = aliceClue
            self.reimuClue = reimuClue
            self.marisaClue = marisaClue
            self.binaryClue = binaryClue
            self.inventory_items = inventory_items
            
    def SaveChoices(): # for a future run
        save = RunSave(attacked_student, garden_of_the_sun_lecture, janitor_talks, revolution, exam_cancelled, investigation_progress, reimu_progress, alice_progress, marisa_progress, time_traveling, asked_office_location, did_not_submit_passcode, has_correct_passcode, chose_reimu_question, first_time_traveling_through_time, time_travel_without_choice, aliceClue, reimuClue, marisaClue, binaryClue, inventory_items)
        return save

    def RestoreChoices(save): # from a past run
        attacked_student = save.attacked_student
        garden_of_the_sun_lecture = save.garden_of_the_sun_lecture
        janitor_talks = save.janitor_talks
        revolution = save.revolution
        exam_cancelled = save.exam_cancelled
        investigation_progress = save.investigation_progress
        reimu_progress = save.reimu_progress
        alice_progress = save.alice_progress
        marisa_progress = save.marisa_progress
        time_traveling = save.time_traveling
        asked_office_location = save.asked_office_location
        did_not_submit_passcode = save.did_not_submit_passcode
        has_correct_passcode = save.has_correct_passcode
        chose_reimu_question = save.chose_reimu_question
        first_time_traveling_through_time = save.first_time_traveling_through_time
        time_travel_without_choice = save.time_travel_without_choice
        aliceClue = save.aliceClue
        reimuClue = save.reimuClue
        marisaClue = save.marisaClue
        binaryClue = save.binaryClue
        inventory_items = save.inventory_items
label start:

    if hedgehog_dilemma_solved.has() or they_have_your_back.has() or she_has_your_back.has():
        jump intro

    label laozi:
        scene bg black
        stop music
        $ renpy.pause(1.5)

        if(persistent.laozi):
            if config.developer == True:
                jump devMode
            else:
                jump presentation_begins

        $ persistent.laozi = True
        $ renpy.save_persistent()
        show text "{alpha=0.2}For this reason the great man dwells in the thick, and does not rest with the thin.{/alpha}\nHe dwells in the {color=#cc2222}fruit{/color}, and does not rest with the {color=#ffff00}flower{/color}.\n                {alpha=0.6}- Laozi, Tao Te Ching{/alpha}" at truecenter
        with dissolve
        $ renpy.pause(6)
        hide text
        with dissolve

    # camera:
    #     perspective True
    #     linear 3.0 zpos 500

    if config.developer == True:
        jump devMode
    else:
        jump presentation_begins

    ### DEV MODE: EXPLORE THE JUNGLE ###

    label devMode:
        $ numOfLabels = len(renpy.get_all_labels())
        $ renpy.say(narrator, "There are currently " + str(numOfLabels) + " unique labels in this project.")

        label IncreaseDay:
            $ day += 1
            $ renpy.notify(day)
            jump DevModePage1

        label DecreaseDay:
            $ day -= 1
            $ renpy.notify(day)
            jump DevModePage1

        label DevModePage1:
            hide screen devModeButtons2
            hide screen devModeButtons3
            show screen devModeButtons1
            hide screen devModeButtons4
            $ ui.saybehavior()
            $ ui.interact()

        label DevModePage2:
            hide screen devModeButtons1
            hide screen devModeButtons3
            show screen devModeButtons2
            hide screen devModeButtons4
            $ ui.saybehavior()
            $ ui.interact()

        label DevModePage3:
            hide screen devModeButtons1
            hide screen devModeButtons2
            show screen devModeButtons3
            hide screen devModeButtons4
            $ ui.saybehavior()
            $ ui.interact()
        
        label DevModeHide:
            hide screen devModeButtons1
            hide screen devModeButtons2
            hide screen devModeButtons3
            hide screen devModeButtons4

    label presentation_begins:
        # TODO
        # TEXT  Y
        # STAGE Y
        # VAR   Y

        image audi_front:
            "bg auditorium front.png"

        image yuuka_look:
            "yuuka looking eyes.png"

        image chills:
            "chills.png"

        show audi_front zorder 150

        show bg auditorium back behind audi_front

        $ renpy.pause(2)
        
        show yuuka neutral behind yuuka_look
        with fade
        
        python: # <- Remove
            '''
            show reimu happy:
                xalign 0.8
                yalign 0.99
            '''

        yuuka "Good evening."

        show yuuka_look
        
        yuuka "You all may know me as the substitute this past week for Professor Okazaki."

        # if config.developer:
        #     show screen time_travel_display_toggle
        # show screen time_travel_display_toggle
        # $ inventory_items.append("Chocolate")

        hide yuuka_look
        show yuuka irritated
        
        yuuka "I've been teaching Botany, a topic on which I am {sc}incredibly{/sc} overqualified for, to idiots younger than you, but still very much similar to you."

        narrator "{i}A few nervous chuckles break throughout the auditorium.{/i}"

        show yuuka amused

        yuuka "But enough of the customary good-natured teasing, I am here because Professor Okazaki is returning today."
        
        show yuuka_look

        yuuka "As is stated in the faculty handbook she wrote and doodled over, because clearly not even she could have handwriting THAT horrendous,"
        
        yuuka "I must give a presentation to report to the faculty and administration exactly what I did as subsitute for Professor Okazaki."

        show yuuka happy

        yuuka "This is that presentation: a postmortem to my short time here, a retrospective of sorts."

        yuuka "You might also be wondering why I've invited select students to attend this presentation."

        yuuka "I will be getting to that, please do not leave your seats throughout this presentation. This will be brief."

    label intro:
        # TODO
        # TEXT  Y
        # STAGE Y
        # VAR   Y

        play music tension if_changed

        scene bg ruinedfield with fade

        $ renpy.pause(2)

        show yuuka rage:
            xalign 0.5
            yalign 0.99
        with dissolve

        yuuka "{i}There I was, one week ago, naive, unsure of what I was looking at.{/i}" (cb_name="")

        yuuka "What the hell am I looking at?"

        if hedgehog_dilemma_solved.has() or they_have_your_back.has() or she_has_your_back.has():

            # forced time travel

            yuuka  "{i}Spring. It was the season for blooming petals, and I had come to one of my second-favorite flower fields in Gensokyo.{/i}" (cb_name="")

            yuuka  "{i}But this time, and I do mean this time my dear audience, I found something more than just a trashed field.{/i}" (cb_name="")

            show yuuka irritated unmarked:
                ease 1.8 ypos 1180

            yuuka "What a confoundingly shaped device."

            yuuka "It reads: {i}\"When does Yuuka want to go?\{/i}"

            yuuka "Is this some kind of prank? Because-"

            scene bg white with flash

            yuuka "{i}And then at that instant I remember it, in flashes and not always clearly but, the future.{/i}" (cb_name="")

            yuuka "{i}The future that had already happened.{/i}" (cb_name="")

            yuuka "W-wha-{nw}"

            yuuka "{i}And then I woke up after this presentation ended. Or will end, I suppose.{/i}" (cb_name="")

            show screen time_travel_display_toggle
            show screen inventory_display_toggle
            $ inventory_items.append("Strange Device")

            jump TT_FinalPresentation

        else:

            yuuka  "{i}Spring. It was the season for blooming petals, and I had come to one of my second-favorite flower fields in Gensokyo.{/i}" (cb_name="")

            yuuka "This used to be a gorgeous field of sunflowers, flowering red buckwheat, growing ever so softly towards the sky blue."

            show yuuka irritated unmarked:
                ease 1.8 ypos 1180

            yuuka "Tell me fallen fauna, by whose footsoles were you trampled?"

            window hide
            $ renpy.pause(1.5)
            # play a wind sound

            show yuuka irritated unmarked:
                ease 1.6 ypos 1080

            yuuka "Sent by a scientist you say? I think I might know who this is."

            yuuka "Very well, then."

            yuuka "I will have to wait until the next spring to enjoy your company, young flowers."

            show yuuka happy:
                ease 1.6 ypos 1080

            yuuka "In the meantime, I think that woman's {sc}bones{/sc} would make for good fertilizer."

        # TODO: Check if we can remove this because its only here for devmode to fix a softlock
        # if config.developer:
        #     $ day = 0

        $ day = 0

    label entrance:
        scene bg entrance with fade
        if day == 0:
            # TODO
            # TEXT  Y
            # STAGE N
            # VAR   N

            yuuka "{i}When I first laid eyes on the school, I found its exterior to be less than appealing to me.{/i}" (cb_name="")

            yuuka "What?"

            yuuka "{i}Now I'm no stranger to different architectural sensibilities, I've had the privilege of owning mansion myself, but we all ought to admit...{/i}" (cb_name="")

            yuuka "The hell am I looking at?"

            yuuka "{i}This school is very out of place for Gensokyo.{/i}" (cb_name="")

            yuuka "Gaudiness aside, this is absolutely where that outsider is."

            yuuka "Now, to call her out here."

            "Excitable Student" "Miss!"

            yuuka "?"

            "Excitable Student" "It's a good thing you're here, on time! Do you need directions?"

            yuuka "I think you have the wrong person, dear."

            "Excitable Student" "You're the subsitute teacher right? I can show you to your class."

            menu:
                "What will Yuuka do?"

                "Make an entrance":
                    # TODO
                    # TEXT  Y
                    # STAGE N
                    # VAR   Y

                    $ attacked_student = True

                    $ marisa_progress += 1

                    show yuuka irritated unmarked:
                        xalign 0.0
                        yalign 0.5
                    with easeinleft

                    yuuka "That won't be necessary, after all..."

                    show yuuka happy:
                        xalign 0.0
                        yalign 0.5

                    yuuka "I've got a landmark don't I?"

                    narrator "A sunflower, each petal the size of a desk, grew out from beneath the stunned student and lifted thme into the air."

                    narrator "The flower tilted to one side and the student rolled off, falling onto the soft grass, as the sunflower grew to eclipse the building."

                    yuuka "Run along then. Save your drivel for someone who cares."

                    show marisa neutral:
                        xalign 1.0
                        yalign 0.5
                    with easeinright

                    show yuuka irritated:
                        xalign 0.0
                        yalign 0.5

                    marisa "I care!"

                    yuuka "Always with the jokes."

                    show marisa laugh:
                        xalign 1.0
                        yalign 0.5

                    marisa "Can't help it when the situation's smelling funny."

                    yuuka "You'd know about smelling funny, little miss thief."

                    show marisa surprise:
                        xalign 1.0
                        yalign 0.5

                    marisa "Thief? I can't believe you'd try to slander me like that!"

                    show marisa happy:
                        xalign 1.0
                        yalign 0.5

                    marisa "I prefer to be called Robin Hood."

                    show yuuka amused:
                        xalign 0.0
                        yalign 0.5

                    yuuka "Because you take from the rich and dress poor?"

                    show marisa surprise:
                        xalign 1.0
                        yalign 0.5

                    marisa "Ack! How you wound me."

                    show marisa happy:
                        xalign 1.0
                        yalign 0.5

                    marisa "Though given you were living it up in a mansion before, not wrong about the first half."

                    show yuuka irritated:
                        xalign 0.0
                        yalign 0.5

                    yuuka "Cut to chase, Marisa. I need to see that scientist friend of yours."

                    show marisa neutral:
                        xalign 1.0
                        yalign 0.5

                    marisa "Oh I'd tell you where Yumemi is, if I knew. But she's not here."

                    yuuka "And I'm to believe you're not lying when you've lied about who you got your oh-so-original Master Spark from?"

                    show marisa serious:
                        xalign 1.0
                        yalign 0.5

                    marisa "Uh, yeah. Because I'm not lying."

                    menu:
                        "Does Yuuka believe her?"

                        "No, obviously.":

                            stop music

                            show yuuka neutral:
                                xalign 0.0
                                yalign 0.5

                            yuuka "..."

                            marisa "..."

                            show marisa neutral:
                                xalign 1.0
                                yalign 0.5

                            marisa "So does that mean..."

                            show yuuka rage:
                                easeout_expo 1.0 xpos 2700
                                yalign 0.5

                            $ renpy.pause(0.85, hard=True)

                            play sound "bowling.mp3"

                            show marisa surprise at damaged, spin, thrown_offscreen:
                                xalign 1.0
                                yalign 0.5
                            
                            yuuka "{i}Then I hit her really hard.{/i}" (cb_name="")

                            marisa ":O"

                            yuuka "From the earth you came, to the dirt you'll bite."

                            show bg black with fade

                            yuuka "{i}Then she was gone, just like that.{nw=2.5}{/i}" (cb_name="")

                            hide bg black
                            scene bg entrance

                            show yuuka happy:
                                xalign 0.0
                                yalign 0.5

                            show marisa serious:
                                xalign 1.0
                                yalign 0.5

                            yuuka "{i}Is what I want to say happened, but we do have spellcard rules for a reason.{/i}" (cb_name="")

                            yuuka "Fine then. If you're not going to concede her, shall we duel?"

                            show marisa concerned:
                                xalign 1.0
                                yalign 0.5

                            marisa "Every spellcard duel begins with a misunderstanding, they say."

                            show marisa defiant:
                                xalign 1.0
                                yalign 0.5

                            marisa "I'm not gonna even try to explain myself then! Let the bullets do the talking!"

                            show yuuka irritated unmarked:
                                xalign 0.0
                                yalign 0.5

                            yuuka "Lets."

                            # TODO: lots of blasty sfx and explosions

                            yuuka "{i}Of course, the scientist really wasn't there.{/i}" (cb_name="")

                            yuuka "{i}And by the time our battle ended, I had taken much of my anger out on the blonde punching bag.{/i}" (cb_name="")

                            yuuka "{i}I vowed to return.{/i}" (cb_name="")

                            yuuka "{i}Justice would come back around for the field one way or another, and I had long term plans to make Yumemi pay.{/i}" (cb_name="")

                            yuuka "{i}But in the meantime, it was just me and a field that needed nurturing and healing now.{/i}" (cb_name="")

                            # TODO: return to presentation

                            yuuka "{i}But that didn't really happen, otherwise I wouldn't be here to talk to you all would I?{/i}" (cb_name="")

                            yuuka "{i}And yet here I am.{/i}" (cb_name="")

                            yuuka "{i}I don't understand how or why.{/i}" (cb_name="")

                            yuuka "{i}I hope you can, in time.{/i}" (cb_name="")

                            yuuka "{i}Best of luck.{/i}" (cb_name="")

                            if long_term.has():
                                "Long Term already has been completed. Consider finding a different ending."

                            $ long_term.grant()

                            jump ending

                        "...yes. Marisa can be trusted.":

                            stop music fadeout 2.0

                            show yuuka neutral:
                                xalign 0.0
                                yalign 0.5

                            yuuka "..."

                            marisa "..."

                            show marisa neutral:
                                xalign 1.0
                                yalign 0.5

                            marisa "So does that mean..."

                            show yuuka irritated unmarked:
                                xalign 0.0
                                yalign 0.5

                            yuuka "Fine, so she's not here?"

                            show marisa neutral:
                                xalign 1.0
                                yalign 0.5

                            marisa "No, but I'm figuring out where she went. "

                            show yuuka neutral:
                                xalign 0.0
                                yalign 0.5

                            yuuka "I see. Any leads?"

                            show marisa concerned:
                                xalign 1.0
                                yalign 0.5

                            marisa "Well, I was trailing your fan until..."

                            narrator "{i}The student was crawling to her feet, awe-struck gaze at Yuuka's newly grown sunflower.{/i}"

                            "Excitable Student" "Wow, miss! You're incredible! What kind of magic is that?"

                            yuuka "The fool doesn't realize who I am?"

                            marisa "We're pretty sure all the humans in this school aren't from Gensokyo."

                            marisa "I'll leave the two of you to it then."

                            show marisa serious:
                                xalign 1.0
                                yalign 0.5

                            marisa "Don't mess this up, teach."

                            show yuuka irritated:
                                xalign 0.0
                                yalign 0.5

                            yuuka "Don't call me tha- and she's gone."

                            narrator "{i}The student approached Yuuka, only slightly rattled.{/i}"

                            "Excitable Student" "I hope we haven't gotten off on the wrong foot! Would you still like me to show the way?"

                            jump icebreakers

                "Go along with it":
                    # TODO
                    # TEXT  Y
                    # STAGE N
                    # VAR   Y

                    show yuuka amused:
                        xalign 0.0
                        yalign 0.5
                    with easeinleft

                    jump icebreakers

            label icebreakers:

                stop music fadeout 2.0

                show yuuka amused:
                    xalign 0.0
                    yalign 0.5
                
                yuuka "Yes, that would be very helpful."

                if attacked_student:
                    yuuka "After tuck her away that is."

                    narrator "{i}Yuuka pointed to the giant flower.{/i}"

                scene bg hallway with fade

                narrator "{i}Led by the student, Yuuka entered the building.{/i}"

                show yuuka amused:
                    xalign 0.0
                    yalign 0.5
                with easeinleft

                yuuka "It's very..."

                "Student" "Modern, isn't it?"

                scene bg classroom with fade

                play sound "classroom.mp3" loop

                show yuuka amused:
                    xalign -0.2
                    yalign 0.5
                with easeinleft

                narrator "{i}The student, leading Yuuka to her class, held the door open for her, letting her get a peek inside.{/i}"

                if not attacked_student:
                    yuuka "Oh, would you look at that? I think there's somewhere else I need to be, th-"

                "Excitable Student" "The substitute's here!"

                "Various Students" "Oh finally. I don't think there's enough time even for a quiz.{nw=1}"

                "Various Students" "I thought we're excused if they're late?{nw=1}"

                "Various Students" "She's kind of fugly with that weird outfit.{nw=1}"
                
                "Various Students" "Huh, what's happening? Is it a test?{nw=1}"

                if not attacked_student:
                    yuuka "{sc}Amusing{/sc} as a misunderstanding this is, I really should be..."

                show yuuka irritated:
                    xalign -0.2
                    yalign 0.5

                show marisa happy:
                    xalign 0.8
                    yalign -0.5
                with easeinbottom

                marisa "Hey teach, how about we get a move on before lunch's on!"

                if attacked_student:
                    yuuka "{i}It was at this moment that I shot a glare at Marisa then took the time actually pick out individual faces from the crowd.{/i}" (cb_name="")
                else:
                    yuuka "{i}It was at this moment that I took the time actually pick out individual faces from the crowd.{/i}" (cb_name="")

                show yuuka neutral:
                    xalign 0.0
                    yalign 0.5
                with ease

                if attacked_student:
                    yuuka "{i}There was Marisa Kirisame, cooled down from our earlier encounter.{/i}" (cb_name="")
                else:
                    yuuka "{i}There was Marisa Kirisame, irritance, thief, and perpetual child as per usual.{/i}" (cb_name="")

                show alice neutral:
                    xalign 1.0
                    yalign -0.5
                with easeinbottom

                yuuka "{i}Sitting next to her was Alice Margatroid, hatchling spawn from Makai, and the relatively reasonable one of the three.{/i}" (cb_name="")

                show reimu serious:
                    xalign 1.2
                    yalign -0.5
                with easeinbottom

                yuuka "{i}Last was Reimu Hakurei, sitting in the back, with a glint in her eye staring back at me.{/i}" (cb_name="")

                yuuka "{i}She seemed to be itching for a fight. That or the stupidity of her face got to me. One of the two.{/i}" (cb_name="")

                if not attacked_student:
                    reimu "A misunderstanding?" (cb_name="")

                yuuka "{i}While I was and forever will be confident in my ability to subdue our militant shrine maiden,{/i}" (cb_name="")

                show yuuka happy:
                    xalign 0.0
                    yalign 0.5

                yuuka "{i}I am a person who can play along. It makes encounters more interesting. I put on my most polite smile and...{/i}" (cb_name="")

                if not attacked_student:
                    yuuka "Yes, class! I'm afraid there will be no tests or lectures today."
                else:
                    yuuka "I'm afraid there will be no tests or lectures today, class."

                narrator "{i}Barely contained cheering erupted throughout the room.{/i}"

                yuuka "Instead we'll be having an {sc}icebreaker{/sc}."

                narrator "{i}Barely contained sighs and groans erupted throughout the room.{/i}"

                hide marisa
                hide alice
                with easeoutbottom

                show reimu surprise:
                    xalign 1.2
                    yalign -0.5

                stop sound fadeout 2.0

                yuuka "You there, in the red and white! Introduce yourself and tell us an interesting fact about yourself."

                yuuka "{i}I could be patient as long as it meant seeing these three flounder.{/i}" (cb_name="")

                reimu "I... uh, what?"

                show yuuka amused:
                    xalign 0.0
                    yalign 0.5

                narrator "{i}Yuuka's smile grew just that bit wider.{/i}"
                
                yuuka "You heard me."

                show marisa laugh:
                    xalign 0.8
                    yalign -0.5
                with easeinbottom

                narrator "{i}There were barely stifled giggles from Marisa's seat as Reimu gaped.{/i}"

                hide marisa surprised
                with easeoutbottom

                narrator "{i}Her hand went to her gohei and glare to Marisa before she realized the class had its eyes on her.{/i}"

                show reimu concerned:
                    xalign 1.2
                    yalign -0.5

                reimu "Well, I'm Reimu Hakurei. I'm a shrine maiden."

                reimu "Uh, interesting facts..."

                show yuuka amused:
                    xalign 0.1
                    yalign 0.5
                with ease

                yuuka "Stand up first, make sure the class can see you, Miss Hakurei."

                show reimu angry:
                    xalign 1.0
                    yalign 0.5
                with ease

                reimu "Tch."

                show yuuka happy:
                    xalign 0.2
                    yalign 0.5
                with ease

                yuuka "What was that now?"

                show reimu serious:
                    xalign 1.0
                    yalign 0.5

                reimu "Nothing."

                narrator "{i}A lull fell for a moment as Reimu collected her thoughts.{/i}"

                show yuuka amused:
                    xalign 0.2
                    yalign 0.5

                yuuka "We haven't got all day, Ms. Hakurei."

                show reimu concerned:
                    xalign 1.0
                    yalign 0.5

                reimu "Well that's... I guess I'm ambidextrous?"

                show yuuka amused:
                    xalign 0.0
                    yalign 0.5
                with ease

                show marisa laugh:
                    xalign 0.8
                    yalign -0.5
                with easeinbottom

                show alice worried:
                    xalign 1.0
                    yalign -0.5
                with easeinbottom

                hide reimu

                show reimu angry:
                    xalign 1.2
                    yalign -0.5
                with ease

                narrator "{i}Marisa then broke out into laughter, unfazed by Alice's glance, and Reimu's melting glare.{/i}"

                marisa "I-I can't, she's really the teacher? They hired HER?"

                show yuuka irritated:
                    xalign 0.0
                    yalign 0.5

                yuuka "You're up next, blondie."

                show marisa surprise:
                    xalign 0.8
                    yalign -0.5

                marisa "Oh, crap."

                scene bg black with fade

                yuuka "{i}The rest of our time left in the class went swimmingly.{/i}" (cb_name="")

                yuuka "{i}Some of you may think I was overly hostile, judgemental, and sadistic on my first day.{/i}" (cb_name="")

                yuuka "{i}To that I will say: That's all? A sign of my excellent restraint.{/i}" (cb_name="")

                yuuka "{i}Afterwards, the trio pulled me aside.{/i}" (cb_name="")

                scene bg hallway with fade

                # four way arrangement of characters with yuuka slightly separated

                show yuuka amused:
                    xalign -0.25
                    yalign 0.5

                show reimu serious:
                    xalign 0.4
                    yalign 0.5

                show marisa neutral:
                    xalign 0.75
                    yalign 0.5

                show alice neutral:
                    xalign 1.10
                    yalign 0.5
    
                reimu "What do you think you're doing, exactly, Yuuka?"

                yuuka "I think you'll find I'm doing exactly as people ought to expect of me."

                reimu "Terrorizing and intimidating the young and innocent?"

                marisa "Invading Gensokyo?"

                alice "Standing in the middle of a field for hours at a time?"

                yuuka "I've not done those since this morning. You know how routines get."

                show yuuka happy

                yuuka "I'm merely here to take a debt owed."

                yuuka "You?"

                reimu "Hm, this school just showed up earlier today. Apparently it's Yumemi's from what the students keep saying."

                show marisa laugh

                marisa "Been a long time since that huh? The scramble for a wish, exploring those ruins..."

                yuuka "{i}Marisa glanced back and forth between all of us.{/i}" (cb_name="")

                alice "I wasn't there."

                yuuka "Neither was I."

                show marisa neutral

                marisa "Great times."

                reimu "Right, anyways we're just here to find her. There've been noise complaints from the Human Village about what they're getting up to here."
                if not attacked_student: 
                    show marisa surprise
                    marisa "Plus, all of the students? They're not from the village. They don't even know they're in Gensokyo!"
                else:
                    show marisa surprise
                    marisa "Plus, all of the students? Like I said, they're not from the village."
                    marisa "They don't even know they're in Gensokyo!"

                show marisa serious

                marisa "We're thinking this is a major breach of the barrier."

                reimu "Except the barrier's entirely untouched."

                alice "But, there's otherwise no evidence of anything done other than some disturbances caused by this school."

                show yuuka rage

                yuuka "{i}A flicker of something worse nearly escaped me. I paused. I was angry. I was here for retribution.{/i}" (cb_name="")

                yuuka "{i}But I'd do no wrong to anyone who didn't deserve it. I would not lash out needlessly.{/i}" (cb_name="")

                show yuuka irritated

                yuuka "Other than the flower field they destroyed?"

                show reimu surprise

                reimu "That's new."

                show yuuka neutral
                yuuka "It's how I found out about this wretched place."

                show reimu serious

                reimu "In any case, we'll keep it in mind. We're going to keep attending as students until we figure this out."

                show yuuka looking

                yuuka "Good, and I will be looking for Yumemi."

                show yuuka neutral

                show marisa laugh

                narrator "{i}Marisa chuckled.{/i}"

                marisa "Yuuka, who do you think you were substituting for?"

                yuuka "...huh?"

                show marisa happy

                marisa "She's out for the week. No one told you, {bt}professor{/bt}?"

                show yuuka rage

                show alice surprise

                show reimu surprise:
                    xalign 0.5
                    yalign 0.5
                show marisa surprise:
                    xalign 0.85
                    yalign 0.5
                with ease

                narrator "{i}Yuuka snarled. Marisa and Reimu stepped back instinctively.{/i}"

                show yuuka irritated at flip

                yuuka "This charade is absurd and I've apparently no reason to be here. Good day to you all."

                hide yuuka
                with easeoutleft

                hide alice
                with easeoutleft

                hide reimu
                hide marisa
                with easeoutright

                yuuka "{i}I stomped my way back through the hallway.{/i}" (cb_name="")

                show yuuka irritated at left
                show alice worried at right
                with dissolve

                yuuka "{i}I was turning the corner before Alice caught up to me.{/i}" (cb_name="")

                alice "Don't you think you're missing an opportunity?"

                yuuka "An opportunity to what?"

                alice "If you stick around, which by the way would be easy given the students have already accepted the fact that you're their teacher,"

                alice "You can just sit tight for a week and Yumemi will walk right into you. No messy incidents, no plotting."

                show yuuka neutral

                yuuka "I could lay a trap."

                alice "Exactly."

                show yuuka irritated

                yuuka "A tempting offer, but I don't think I'll need any tricks to deal with that lout. I'll find her myself."

                show yuuka irritated at flip

                yuuka "{i}Once more I turned away, and...{/i}" (cb_name="")

                show alice angry

                alice "Oh for Shinki's sake, are you scared of something?"

                show yuuka neutral at unflip

                yuuka "What?"

                alice "You talk to humans less than I do and I live in a poisonous swamp of a forest."

                alice "You've barely talked to anyone other than us three after leaving your mansion in Mugenkan years ago."

                show yuuka amused

                yuuka "They're beneath me."

                show yuuka neutral
                
                yuuka "Besides, I talk with Medicine."

                alice "She's one kid. That hardly proves anything."

                show alice worried

                alice "Look, this is the first time I've seen you talk with humans without it being some kind of underlying threat or overlying threat. This could be good for you."

                alice "And besides, even if she isn't here this is HER school. Her possessions, her office, they'd all be here. If you're going on a crusade, why leave?"

                yuuka "I..."

                alice "Before anything else, I have one last thing to say."
                
                alice "It's a week. Just a week. At least come in tomorrow and give it a shot?"

                yuuka "..."

                yuuka "I do not agree with your points, Alice."

                show yuuka amused

                yuuka "But I consider you to know me better than most."

                yuuka "Very well, I'll play along."

                show alice happy

                alice "Thank you. That's all I'm asking."

                show yuuka neutral at flip

                yuuka "I'll be back tomorrow. Goodbye Alice."

                alice "Goodbye."

                $ day = 1

                $ next_label = "classroom"
                jump day_transition
        elif day == 1:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        elif day == 2:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        elif day == 3:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        elif day == 4:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        else:
            "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
            return

    label classroom:
        # Day 0 excluded
        if day == 1:
            # TODO
            # TEXT  Y
            # STAGE N
            # VAR   Y
            label lecture_intro:
                scene bg entrance with fade

                yuuka "I'm back here again."

                yuuka "Alice may be a busybody but she means well enough."

                yuuka "The only question is if I'm actually going along with this or... if I should at least get some fun out of this?"

                yuuka "And after all, I should get something in return for what I give them."

                menu:
                    "What does Yuuka give them?"

                    "Sunflowers {i}(matter-of-fact){/i}":
                        yuuka "Oh fine then. Alice is so insistent on me interacting with humans? Sure, no problems here."

                        yuuka "But what am I even teaching?"

                        scene bg classroom with fade

                        jump lecture

                    "Sunflowers {i}(scheming){/i}":
                        yuuka "Oh fine then. Alice is so insistent on me interacting with weaklings? Sure, no problems here."

                        yuuka "Especially, if I get a chance to shut them up."

                        $ garden_of_the_sun_lecture = True

                        scene bg garden with fade

                        jump lecture

                label lecture:
                    yuuka "Good morning, class."

                    marisa "Uh, teach-"

                    yuuka "Teacher. It's teacher, not teach."

                    if garden_of_the_sun_lecture:
                        marisa "Right... so teacher, why are we here?"

                        yuuka "I don't see why not? It's a perfectly nice place to have our class today."

                        narrator "{i}Marisa took a look at the students around her, confused but unaware they were on the territory of a dangerous, powerful youkai.{/i}"

                    marisa "...sure."

                    yuuka "Now, let's begin shall we?"

                    yuuka "I'd like for us to go over some botany."

                    if attacked_student:
                        "Various Students" "She's really good at that! She made a giant flower bloom yesterday!{nw=1}"
                        "Various Students" "We know, it's still there.{nw=1}"
                        "Various Students" "Isn't it magic not botany?{nw=1}"

                    yuuka "Tsk, tsk. You'd think Professor Okazaki would've taught you better."

                    yuuka "Botany is the study of plants and though we might call some things we do as being magic, that doesn't mean it can't be both."

                    yuuka "Ket's talk about one kind of plant in specific actually."

                    yuuka "The sunflower."

                    if garden_of_the_sun_lecture:
                        yuuka "{i}I sweeped my arms around to gesture at the garden, each sunflower standing tall.{/i}" (cb_name="")
                    else:
                        yuuka "{i}I brought out a potted sunflower I had prepared for today.{/i}" (cb_name="")

                    yuuka "We all know that plants grow facing towards the sun, seeking sustenance, seeking the good source of life."

                    yuuka "But were you aware they also react to other things?"

                    if garden_of_the_sun_lecture:
                        yuuka "{i}The sunflowers around us began to turn their faces towards my lecture.{/i}" (cb_name="")
                    else:
                        yuuka "{i}The sunflower began to turn its face towards my students.{/i}" (cb_name="")

                    yuuka "Chemicals, sounds, temperature changes..."

                    yuuka "{i}The students began to react, gasping, pointing.{/i}" (cb_name="")

                    yuuka "...disease, infection, {sc}parasites{/sc}."

                    if garden_of_the_sun_lecture:
                        yuuka "{i}You could hear the chill going down their backs when they heard that.{/i}" (cb_name="")

                        yuuka "And here you are. A group of {sc}flower-trampling, clumsy-limbed mouth-breathers who trample where they please{/sc}."

                        yuuka "A question for participation points: who are the parasites here?"

                        yuuka "{i}Alice got up, worried as she usually is.{/i}" (cb_name="")

                        alice "Hold on, Yuuka. You can't-"

                        yuuka "Do not waste the time of the class, Miss Margatroid. Answer the question or sit down."

                        narrator "{cps=1}...{/cps}"

                        yuuka "If no one will answer the question, then let me give a hands-on demonstration."

                        yuuka "{i}The sunflowers rushed, rapidly surrounding the students, stems twisting towards the sky.{/i}" (cb_name="")

                        yuuka "{i}The students seemed to be getting the picture by then, the situation dawning on their gaping faces.{/i}" (cb_name="")

                        reimu "Stop it!"

                        yuuka "Oh, does one of our own have an answer?"

                        reimu "Save it for the spellcards, Yuuka."

                        yuuka "Fine then. Shall we duel?"

                        reimu "Three spell cards. Don't touch any of the students or I'll {sc}exterminate{/sc} you."

                        yuuka "But of course. It was just a demonstration."

                        # TODO: lots of blasty sfx and explosions

                        yuuka "{i}By the time our battle ended, I had taken much of my anger out on the shrine maiden.{/i}" (cb_name="")

                        yuuka "{i}But the human students seemed to understand by then, instinctively, what kind of being I am.{/i}" (cb_name="")

                        yuuka "{i}They didn't have to wait for my permission to start running away.{/i}" (cb_name="")

                        yuuka "{i}That, of course, ended my brief teaching career.{/i}" (cb_name="")

                        yuuka "{i}My retribution on Yumemi would have to wait for another opportunity.{/i}" (cb_name="")

                        ####

                        yuuka "{i}But that didn't really happen, otherwise I wouldn't be here to talk to you all would I?{/i}" (cb_name="")

                        yuuka "{i}And yet here I am.{/i}" (cb_name="")

                        yuuka "{i}I don't understand how or why.{/i}" (cb_name="")

                        yuuka "{i}I hope you can, in time.{/i}" (cb_name="")

                        yuuka "{i}Best of luck.{/i}" (cb_name="")

                        if scare_tactics.has():
                            "Scare Tactics already has been completed. Consider finding a different ending."

                        $ scare_tactics.grant()

                        jump ending

                    else:
                        yuuka "{i}They took to my \"sense of humor\" well enough, earning one or two chuckles, if stressed ones.{/i}" (cb_name="")

                        yuuka "They are living things just like any of you, smarter, more articulate than you could imagine."

                        yuuka "Has anyone here heard of the language of flowers?"

                        narrator "{i}One or two hands went up.{/i}"

                        yuuka "In the back row."

                        "Excitable Student" "It's the use of flowers as symbolism in poetry and letters: telling things without saying them directly."

                        yuuka "Not entirely wrong but it extends past use OF flowers. Rather, it is the language that flowers themselves use."

                        yuuka "Today, I'll be teaching you all to learn to listen, not just to me, but to the flowers. If you can learn to hear their voices, there may be hope for you yet."

                        yuuka "{i}And really, I was staking Alice's plea on this.{/i}" (cb_name="")

                        yuuka "{i}A week of my time is a valuable thing, so unless there were results, I would not wait.{/i}" (cb_name="")

                        yuuka "Split off into groups of three, pick your members yourself you're old enough not to need to be babied."

                        yuuka "I've brought one sunflower for each group and I want you all to try and discern what your flower is telling you."

                        "Various Students" "This is crazy.{nw=1.0}"
                        "Various Students" "We're listening to flowers talk now?{nw=1.0}"
                        "Various Students" "Well, we are learning magic aren't we?{nw=1.0}"
                        "Various Students" "Magic that can't be understood is indistinguishable from...{nw=1.0}"
                        "Various Students" "It's CAN be understood not CAN'T, you dolt.{nw=1.0}"

                        yuuka "Do not harm any of the flowers. You {sc}WILL{/sc} pay your debt if you do."

                        narrator "Marisa, Alice, and Reimu shivered."

                        yuuka "Now get to it! We'll discuss the results in 15 minutes."

                        scene bg black with fade

                        $ renpy.pause(1.0)

                        marisa "Hey, teach! I think my flower's broken!"

                        alice "I'm not getting anywhere with this."

                        narrator "Reimu was the only one out of the three still taking the assignment seriously."

                        reimu "Listen to their voice..."

                        yuuka "{i}She was staring at her group's potted plant so hard you'd think she'd burn a hole.{/i}" (cb_name="")

                        marisa "I guess you'd be pretty used to this kind of thing, huh Reimu?"

                        alice "Marisa, shut up. Let her focus."

                        reimu "{cps=1}...{/cps}{nw}"

                        reimu "...{fast}I've got nothing."

                        yuuka "Let's wrap this up class! Return to your seats."

                        yuuka "{i}After that, the session continued on/ For the most part, no one felt they managed to hear the sunflowers' voices.{/i}" (cb_name="")

                        yuuka "{i}But...{/i}" (cb_name="")

                        "Various Students" "But don't you think they're pretty? I wonder if they could sense radiation.{nw=1.0}"

                        "Various Students" "For your sake, I hope you don't test that out. I don't know how much our substitute was joking.{nw=1.0}"

                        "Various Students" "Actually, we can't just call her the substitute for the whole week right? What is her nam{nw}"

                        "Various Students" "I dunno about you guys but I think my sunflower can hear me.{nw=1.0}"

                        yuuka "{i}There was more enthusiasm than I had expected.{/i}" (cb_name="")

                        yuuka "{i}Still I had made my decision.{/i}" (cb_name="")

                        scene bg black with fade

                        jump hallway
            return
        elif day == 2:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        elif day == 3:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        elif day == 4:
            # TODO
            # TEXT  N
            # STAGE N
            # VAR   N
            window show # placeholder
            return
        else:
            "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
            return

# TODO: SKIPPING THE YUUKA PART OF THE STAGE DIRECTIONS IN THIS AREA FOR NOW
# side character stuff here and the puzzle
label hallway:

    scene bg hallway with fade

    if day == 1:
        # TODO
        # TEXT  Y
        # STAGE Y
        # VAR   Y

        $ did_not_visit_faculty = True

        $ did_not_visit_auditorium = True

        $ did_not_visit_classroom = True
        
        if(time_traveling):
            yuuka "Back here, huh?"
        else:
            yuuka "What a waste of time."

        label hallway_navigation:

            scene bg hallway with fade

            menu:
                "Where does Yuuka go?"
                "Exit school":

                    scene bg black with fade

                    if(reimu_progress < 1):
                        
                        yuuka "{i}And leave I did.{/i}" (cb_name="")

                        yuuka "{i}I vowed to return.{/i}" (cb_name="")

                        yuuka "{i}Justice would come back around for the field one way or another, and I had long term plans to make Yumemi pay.{/i}" (cb_name="")

                        yuuka "{i}But in the meantime, it was just me and a field that needed nurturing and healing now.{/i}" (cb_name="")

                        yuuka "{i}Admittedly, there might've been something akin to potential in those students.{/i}" (cb_name="")

                        yuuka "{i}However, they failed my simplest of tasks.{/i}" (cb_name="")

                        yuuka "{i}In truth, the flowers speak for everyone even if I'm the only one who can hear them.{/i}" (cb_name="")

                        yuuka "{i}Sad isn't it? To be heard by only one person in the world.{/i}" (cb_name="")

                        yuuka "{i}...{/i}" (cb_name="")

                        yuuka "{i}But that didn't really happen, otherwise I wouldn't be here to talk to you all would I?{/i}" (cb_name="")

                        yuuka "{i}And yet here I am.{/i}" (cb_name="")

                        yuuka "{i}I don't understand how or why.{/i}" (cb_name="")

                        yuuka "{i}I hope you can, in time.{/i}" (cb_name="")

                        yuuka "{i}Best of luck.{/i}" (cb_name="")

                        if long_term.has():
                            "Long Term already has been completed. Consider finding a different ending."

                        $ long_term.grant()
                        jump ending
                    else:

                        yuuka "{i}I left the school not assuaged but...{/i}" (cb_name="")

                        yuuka "{i}Feeling a little lighter.{/i}" (cb_name="")

                        $ day = 2

                        $ next_label = "faculty"

                        jump day_transition

                "Go to the faculty room" if did_not_visit_faculty:

                    scene bg faculty with fade

                    $ did_not_visit_faculty = False

                    if(not asked_office_location):

                        "Faculty Member" "Ah, looking for something?"

                        yuuka "I was just wondering where Professor Okazaki's teaching materials are, I was hoping to take a look at them."

                        yuuka "{i}And destroy it so I'd see the look on her face when she returns.{/i}"

                        "Faculty Member" "She didn't share it with you? Odd, but she has her own office."

                        "Faculty Member" "It's around the corner, behind a keypad. Did she tell you the passcode?"

                        yuuka "No, I believe I was too late to catch her before she left."

                        "Faculty Member" "Well that's a shame, for all she gushes about technology, her office, her phone, she's a difficult person to contact."

                        "Faculty Member" "You'd know her better than me, probably. It's a four-digit code, can't be that hard to guess right?"

                        yuuka "...sure."

                        $ asked_office_location = True
                    else:
                        yuuka "Nothing of importance here."

                    jump hallway_navigation

                "Go to the auditorium" if did_not_visit_auditorium:

                    scene bg auditorium with fade

                    yuuka "{i}It's where we are now. But at the time, it was empty.{/i}" (cb_name="")

                    yuuka "Nothing of importance here."
                    
                    # show screen inventory_display_toggle
                    # $ inventory_items.append("Chocolate THIS IS A TEST")

                    $ did_not_visit_auditorium = False
                    jump hallway_navigation

                "Go to her classroom" if did_not_visit_classroom:

                    scene bg classroom with fade

                    yuuka "{i}I walked over to the classroom, opening the door.{/i}" (cb_name="")

                    yuuka "Empty."

                    "???" "Lookin' for someone?"

                    # reimu appears

                    show reimu serious with dissolve

                    yuuka "Oh. It's you."

                    yuuka "{i}She rolled her eyes at that one.{/i}" (cb_name="")

                    reimu "I have a name you can use, you know."

                    yuuka "Most people do."

                    reimu "Yeah."

                    reimu "{cps=1}...{/cps}"

                    reimu "Are you looking for something?"

                    yuuka "Nothing in particular."

                    reimu "Mhm."

                    narrator "{cps=1}...{/cps}"

                    yuuka "I should go-{nw}"

                    reimu "When I said I had nothing, during the activity earlier."

                    reimu "I meant I didn't hear anything."

                    reimu "I did feel... something?"

                    yuuka "Is that so?"

                    reimu "It was a passing sensation, just an instant, nearly nothing really."

                    show reimu happy

                    reimu "Still, I'm looking forward to you next class."

                    yuuka "...I see. Thank you for telling me that, Reimu."

                    hide reimu with dissolve

                    yuuka "{i}And then I left without waiting for a response, her footsteps in the opposite direction from mine.{/i}" (cb_name="")

                    $ did_not_visit_classroom = False
                    $ reimu_progress += 1
                    jump hallway_navigation

                "Wait here" if janitor_talks == 0:

                    $ janitor_talks = 1

                    if("Keycard" in inventory_items):
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation

                    if(has_correct_passcode):

                        show yumemi disguise with dissolve

                        janitor "Hey youngster."

                        janitor "Looks like you've been workin' hard huh? Or hardly workin'?"

                        yuuka "Har, har."

                        show screen inventory_display_toggle
                        $ renpy.notify("Keycard gotten.")
                        $ inventory_items.append("Keycard")

                        janitor "Anyhow, here ya go."

                        hide yumemi with dissolve

                        yuuka "?"

                        yuuka "Hold on, this is!"

                        yuuka "Wait, where'd she go?"

                    else:

                        yuuka "It's exhausting, hamming it up for so many people."

                        yuuka "{i}I stood there, learning against a wall, not sure what I was waiting for when a cup of tea with my name was at home.{/i}" (cb_name="")

                        janitor "Hm, you tha' new substitute teacher?"

                        show yumemi disguise with dissolve

                        yuuka "{i}I, of course, did not deign to turn my head to look at whoever was talking to me.{/i}" (cb_name="")

                        "???" "You younguns', tsk, tsk. No respect for 'ur elders."

                        # TODO: Yumemi in bad janitor disguise appears

                        janitor "Ya mind standin' somewhere else so I can clean?"

                        yuuka "..."

                        janitor "Suit 'urself, whippersnapper."

                    # janitor leaves
                    
                    jump hallway_navigation

                "Go to Yumemi's office" if did_not_submit_passcode and asked_office_location:

                    scene bg hallway at flip with fade

                    if(time_traveling):
                        yuuka "Here we are again."
                        yuuka "I better pick carefully."
                    else:
                        yuuka "Here we are."
                        yuuka "Gotta say, it looks like any other door I've seen. Except for the keypad that is."

                    menu:
                        "Does Yuuka enter a passcode?"

                        "Yes.":
                            $ passcode_attempt = renpy.input("ENTER FOUR DIGIT PASSCODE", allow="0123456789", length=4)
                            if(passcode_attempt == "0110"):
                                $ has_correct_passcode = True
                                yuuka "And ...it hasn't locked out on me yet."
                                "SCAN KEYCARD TO COMPLETE ENTRY"
                                if("Keycard" in inventory_items):
                                    yuuka "Scan it... how do you make this dreadful thing work?"

                                    yuuka "Uh huh, uh, okay. There we go."

                                    "KEYCARD CORRECT"

                                    "WELCOME PROFESSOR OKAZAKI"

                                    scene bg black

                                    yuuka "{i}Now I won't spoil exactly what I saw in that office but I will say.{/i}" (cb_name="")

                                    yuuka "{i}In addition to finding the exam data, stored in some kind of machinery that I deigned not to try to understand,{/i}" (cb_name="")

                                    yuuka "{i}Which is to say that I smashed it to little metal bits with great delight.{/i}" (cb_name="")

                                    yuuka "{i}There was also an intriguing absence of any time machine device, save for an opened safe that looked like it could've stored the device I hold now.{/i}" (cb_name="")

                                    yuuka "{i}Now, I'm not one for paradoxes...{/i}" (cb_name="")

                                    yuuka "{i}...{/i}" (cb_name="")

                                    yuuka "{i}And that's all I have to say on that subject.{/i}" (cb_name="")

                                    jump finale
                                else:
                                    yuuka "A keycard!? You mean I've been working my ass off to just get another lock?"

                                    yuuka "Fuck this. I'm out."
                            else:
                                if(time_traveling):
                                    yuuka "And... crap."
                                    yuuka "Wrong again."
                                else:
                                    yuuka "And that should be... wrong. Great."
                                    yuuka "Oh, and would you look at that, it's locked me out. Wonderful."
                                    yuuka "Damn it, that might've been my only try at this."
                                    yuuka "Fine then, maybe I ought to pivot to focusing on Yumemi herself instead of bothering with what she owns."
                                    yuuka "...or I could bust this door down."
                                    yuuka "Nah, saying it out loud makes it obvious that's just asking for people to turn on me. I'll find another approach to this."

                        "No, not yet.":
                            jump hallway_navigation

                    jump hallway_navigation
    elif day == 2: # consultations
        # TODO
        # TEXT  Y
        # STAGE Y
        # VAR   Y

        $ did_not_visit_faculty = True

        $ did_not_visit_auditorium = True

        $ did_not_visit_classroom = True

        if(time_traveling):
            yuuka "Consultations, right. That's how I found out I wasn't even teaching the same subject as Yumemi."
        else:
            yuuka "I need to talk to the other teachers."

        label hallway_navigation2:

            scene bg hallway with fade

            menu:
                "Where does Yuuka go?"

                "Exit school":
                    if did_not_visit_faculty:
                        yuuka "I can't yet."
                        jump hallway_navigation2
                    else:
                        
                        scene bg black with fade

                        yuuka "I went home."

                    $ day = 3

                    $ next_label = "exam"

                    jump day_transition

                "Go to the faculty room" if did_not_visit_faculty:

                    scene bg faculty with fade

                    # yuuka petitions that they revise the exam
                    # they explain that its yumemi's exam materials that are printed wirelessly but if she wants to rewrite them individually and manually she's free to do so
                    # she holds that they should all do it

                    if(not asked_field_faculty):
                        yuuka "There's something I wanted to ask."
                        
                        "Faculty Member" "Yes?"
                        
                        yuuka "There was this field I was fond of, not too far from here. It's been {sc}DESTROYED{/sc} since, do you know what happened?"
                        
                        "Faculty Member" "Ah. Apologies but I don't think I've heard about that."
                        
                        yuuka "I see."
                        
                        "Faculty Member" "What a shame... I think I've seen that same field."
                        
                        "Faculty Member" "When will we stop this shameless destruction?"
                        
                        yuuka "We? This school has done {sc}similar{/sc} things before?"
                        
                        "Faculty Member" "God, I hope not."
                        
                        "Faculty Member" "I'm just speaking in general, about all of humanity."
                        
                        "Faculty Member" "We've devastated the world enough, haven't we? Not that our leaders listen."
                        
                        yuuka "...no, they certainly don't. I'm glad to see you understand."
                        
                        yuuka "..."
                        
                        $ asked_field_faculty = True
                    
                    elif(not asked_office_location):

                        "Faculty Member" "Ah, looking for something?"

                        yuuka "I was just wondering where Professor Okazaki's teaching materials are, I was hoping to take a look at them."

                        yuuka "{i}And destroy it so I'd see the look on her face when she returns.{/i}"

                        "Faculty Member" "She didn't share it with you? Odd, but she has her own office."

                        "Faculty Member" "It's around the corner, behind a keypad. Did she tell you the passcode?"

                        yuuka "No, I believe I was too late to catch her before she left."

                        "Faculty Member" "Well that's a shame, for all she gushes about technology, her office, her phone, she's a difficult person to contact."

                        "Faculty Member" "You'd know her better than me, probably. It's a four-digit code, can't be that hard to guess right?"

                        yuuka "...sure."

                        yuuka "I have another concern actually."

                        $ asked_office_location = True
                    else:
                        "Faculty Member" "Ah, Miss... uh-"

                    yuuka "We need to make some last-minute adjustments to the exam."

                    "Faculty Member" "Adjustments?"

                    yuuka "To incorporate some recent curriculum changes."

                    "Faculty Member" "It's quite late for those but even if we wanted to, the exams are automatically printed by Professor Okazaki's wireless printer."

                    "Faculty Member" "Given she's not here, it's too late to make any changes."

                    yuuka "But, we have pens and blank paper, yes?"

                    "Faculty Member" "Yes, but I'm not sure what you're getting at?"

                    yuuka "We write up the exam by hand."

                    "Faculty Member" "That would take terribly long."

                    yuuka "Well..."

                    show yuuka rage with easeinbottom

                    yuuka "{sc}WE{/sc} better get started."

                    $ day = 3

                    $ next_label = "exam"

                    $ did_not_visit_faculty = False

                    jump day_transition

                "Go to the auditorium" if did_not_visit_auditorium:

                    # another scene with reimu

                    scene bg auditorium with fade

                    if "Clue #1" in inventory_items:
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation2

                    yuuka "...no one here."

                    yuuka ""

                    if(reimu_progress > 0):

                        "???" "We seem to running into each other a lot."

                    else:

                        "???" "Used to be a rare thing, running into you. I guess we might keep doing that while we're here, huh."

                    show reimu serious with dissolve

                    yuuka "It's a school and we both go to the same classroom. I'm not sure we could avoid each other if we tried."

                    reimu "I'm sure you'd manage."

                    yuuka "How was the lecture today?"

                    if chose_reimu_question:
                        
                        show reimu happy

                        reimu "Good. I think I got some clarification into what exactly we're learning."

                        yuuka "And what are you learning exactly?"
                    
                        show reimu sleepy

                        reimu "Not quite what you think we are."

                        yuuka "?"

                        reimu "What about poor Marisa though? She had her own question."

                        yuuka "Knowing her it'd be inane. Besides..."

                    else:
                        
                        show reimu concerned

                        reimu "I'm a bit sad I didn't get my question answered."

                        yuuka "Well I can't exactly bend to all of your wills at once now can I?"

                    yuuka "I'm rather outnumbered, you must understand. Would you think cutting a few down to size could help with that?"

                    show reimu sleepy

                    reimu "Don't go for Marisa. She needs the blood to live."

                    yuuka "And you don't?"

                    reimu "I'll borrow some from Marisa."

                    yuuka "I don't suppose us, youkai count for that then."

                    show reimu happy

                    reimu "I'm sure a little pain can't hurt."

                    yuuka "It most assuredly can and does. And bisecting a person into two isn't a little."

                    reimu "Not for most."

                    "..."

                    yuuka "You're not going to ask about the exams?"

                    reimu "I'm... choosing to trust you on this."

                    reimu "For now."

                    yuuka "Thank you, Reimu."

                    show reimu sleepy

                    reimu "No problem."

                    if(reimu_progress > 0):

                        show reimu serious
                        
                        reimu "Hey, and I wanted to ask if you saw Yumemi's office?"

                        if asked_office_location:
                            yuuka "I know of it, if that's what you're asking."
                        else:
                            yuuka "No."

                            reimu "You should. Ask around about it."
                        
                        reimu "I think there's something important inside. Marisa says we shouldn't try and brute force in and I'm inclined to agree."

                        reimu "It seems perfectly in-character for Yumemi to have put some measures that'll inevitably bite us in the ass if we try to break in."

                        yuuka "Why don't you try to figure it out then?"

                        show reimu concerned

                        reimu "I'm still trying to talk to the faculty around here, get any info about some suspicious type in the hallways."

                        reimu "Not you, of course."

                        yuuka "...right."

                        show reimu serious

                        reimu "Whatever Yumemi has planned, is big, like orders of magnitude bigger than we first thought."

                        yuuka "Orders of magnitude... you think she might play into that for the passcode? Something grand?"

                        reimu "I don't know how grand you can get in four digits but sure. That's probable."

                        show screen inventory_display_toggle
                        $ renpy.notify("Clue #1 gotten.")
                        $ inventory_items.append("Clue #1")

                        show reimu sleepy

                        reimu "I'll be seeing you around then."

                        yuuka "Thank you, again, Reimu."

                        reimu "Bye, Yuuka."

                    $ did_not_visit_auditorium = False
                    $ reimu_progress += 1
                    jump hallway_navigation2

                "Go to her classroom" if did_not_visit_classroom:

                    scene bg classroom with fade

                    if "Clue #3" in inventory_items:
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation2

                    # a scene with alice

                    show alice happy at flip with dissolve

                    yuuka "Fancy seeing you here."

                    show alice surprise at unflip

                    alice "Oh!"

                    show alice happy

                    alice "Nice to see you too, Yuuka."

                    if "Clue #1" in inventory_items and "Clue #2" in inventory_items:
                        yuuka "Alice, I've been trying to figure a way into Yumemi's office."

                        yuuka "I've gone over it with Reimu and Marisa and we've just made guesses about what it could be."

                        yuuka "I'm hoping I could ask if you have any ideas yourself?"

                        alice "Well... I think there's one thing."

                        alice "Yumemi's a woman of science, through and through."

                        alice "She loves ordering chaos, making sense of the supernatural, mastering magic as a science."

                        alice "I admire it to a degree, though I think she's strangling the beauty of magic when she does as far as to make it into a science."

                        alice "That said, she'd probably pick a passcode that is orderly, symmetrical even."

                        yuuka "Like one of those... anagrams?"

                        alice "That's for two words that use the same letters and so can be rearranged to form one or the other."
                        
                        alice "There are also ambigrams, which is what I mean. It's spelled backwards the same way as it's spelled forwards."

                        alice "There are a few other types, I have a fondness for 90° ambigrams myself."

                        show screen inventory_display_toggle
                        $ renpy.notify("Clue #3 gotten.")
                        $ inventory_items.append("Clue #3")

                        yuuka "Thank you, Alice. That might be what I need to figure this out."

                        alice "...you're welcome, Yuuka. Good luck."

                        $ did_not_visit_classroom = False
                        $ alice_progress += 1
                        jump hallway_navigation2
                    elif "Clue #1" in inventory_items or "Clue #2" in inventory_items:
                        yuuka "Mhm. I was wondering about..."

                        yuuka "Actually, nevermind."

                    else:
                        yuuka "Mhm."

                        narrator "..."

                    alice "You know, if you have a question to ask, you can always ask me."
                    
                    if "Clue #1" in inventory_items or "Clue #2" in inventory_items:
                        yuuka "I'm being a little obvious aren't I?"

                        show alice happy

                        alice "A little."

                    else:
                        yuuka "You can tell?"

                        show alice neutral

                        alice "I've been around you long enough to."

                        show alice angry

                        alice "Sometimes you act before you think, but other times you just don't know who to talk to."

                        show alice happy

                    alice "If it's about the exam, the flower field, your garden, or anything at all you can always ask."

                    yuuka "I... thank you."

                    yuuka "I'll think about it."

                    show alice neutral

                    alice "That's good."

                    yuuka "And you? Is there anything you'd want to share with me?"

                    show alice happy

                    alice "...not at the moment."

                    yuuka "Then, I'll be seeing you tomorrow, Alice."

                    alice "Goodbye, Yuuka."
                    
                    $ did_not_visit_classroom = False
                    $ alice_progress += 1
                    jump hallway_navigation2

                "Wait here" if janitor_talks < 2:

                    $ janitor_talks = 2

                    if("Keycard" in inventory_items):
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation2

                    if(has_correct_passcode):

                        show yumemi disguise with dissolve

                        janitor "Hey youngster."

                        janitor "Looks like you've been workin' hard huh? Or hardly workin'?"

                        yuuka "Har, har."

                        show screen inventory_display_toggle
                        $ renpy.notify("Keycard gotten.")
                        $ inventory_items.append("Keycard")

                        janitor "Anyhow, here ya go."

                        hide yumemi with dissolve

                        yuuka "?"

                        yuuka "Hold on, this is!"

                        yuuka "Wait, where'd she go?"

                    else:

                        janitor "Ya ever see anything like it?"

                        show yumemi disguise with dissolve

                        yuuka "{i}Caught up in my own waiting I did not respond.{/i}" (cb_name="")

                        janitor "When the students are out, this place's a lot prettier."

                        janitor "'course that's cause of me."

                        yuuka "..."

                        janitor "See ya in January, green-hair."

                        hide yumemi with dissolve
                        
                        yuuka "Classes don't even end in J-"

                        yuuka "And she's gone."

                    jump hallway_navigation2
                "Go to Yumemi's office" if did_not_submit_passcode and asked_office_location:

                    scene bg hallway at flip with fade

                    if(time_traveling):
                        yuuka "Here we are again."
                        yuuka "I better pick carefully."
                    else:
                        yuuka "Here we are."
                        yuuka "Gotta say, it looks like any other door I've seen. Except for the keypad that is."

                    menu:
                        "Does Yuuka enter a passcode?"

                        "Yes.":
                            $ passcode_attempt = renpy.input("ENTER FOUR DIGIT PASSCODE", allow="0123456789", length=4)
                            if(passcode_attempt == "0110"):
                                $ has_correct_passcode = True
                                yuuka "And ...it hasn't locked out on me yet."
                                "SCAN KEYCARD TO COMPLETE ENTRY"
                                if("Keycard" in inventory_items):
                                    yuuka "Scan it... how do you make this dreadful thing work?"

                                    yuuka "Uh huh, uh, okay. There we go."

                                    "KEYCARD CORRECT"

                                    "WELCOME PROFESSOR OKAZAKI"

                                    scene bg black

                                    yuuka "{i}Now I won't spoil exactly what I saw in that office but I will say.{/i}" (cb_name="")

                                    yuuka "{i}In addition to finding the exam data, stored in some kind of machinery that I deigned not to try to understand,{/i}" (cb_name="")

                                    yuuka "{i}Which is to say that I smashed it to little metal bits with great delight.{/i}" (cb_name="")

                                    yuuka "{i}There was also an intriguing absence of any time machine device, save for an opened safe that looked like it could've stored the device I hold now.{/i}" (cb_name="")

                                    yuuka "{i}Now, I'm not one for paradoxes...{/i}" (cb_name="")

                                    yuuka "{i}...{/i}" (cb_name="")

                                    yuuka "{i}And that's all I have to say on that subject.{/i}" (cb_name="")

                                    jump finale
                                else:
                                    yuuka "A keycard!? You mean I've been working my ass off to just get another lock?"

                                    yuuka "Fuck this. I'm out."
                            else:
                                if(time_traveling):
                                    yuuka "And... crap."
                                    yuuka "Wrong again."
                                else:
                                    yuuka "And that should be... wrong. Great."
                                    yuuka "Oh, and would you look at that, it's locked me out. Wonderful."
                                    yuuka "Damn it, that might've been my only try at this."
                                    yuuka "Fine then, maybe I ought to pivot to focusing on Yumemi herself instead of bothering with what she owns."
                                    yuuka "...or I could bust this door down."
                                    yuuka "Nah, saying it out loud makes it obvious that's just asking for people to turn on me. I'll find another approach to this."

                        "No, not yet.":
                            jump hallway_navigation
    elif day == 3:
        # TODO
        # TEXT  Y
        # STAGE N
        # VAR   Y

        $ did_not_visit_faculty = True

        $ did_not_visit_auditorium = True

        $ did_not_visit_classroom = True

        $ skip_bulk_classroom = False

        if(time_traveling):
            yuuka "Back to exam day."
        else:
            yuuka "They seemed to enjoy that exam. I'm... I'm glad."

        label hallway_navigation3:

            scene bg hallway with fade

            menu:
                "Where does Yuuka go?"

                "Exit school":
                    scene bg black with fade
                    yuuka "{i}Of course, I went home.{/i}" (cb_name="")

                    yuuka "{i}I had to be up and rested for today.{/i}" (cb_name="")
                    
                    yuuka "{i}Let's do a run through of said day, shall we?{/i}" (cb_name="")

                    $ day = 4
                    
                    $ next_label = "penultimate_presentation"
                    jump day_transition

                "Go to the faculty room" if did_not_visit_faculty:
                    scene bg faculty with fade
                    
                    if(not asked_field_faculty):
                        yuuka "There's something I wanted to ask."
                        
                        "Faculty Member" "Yes?"
                        
                        yuuka "There was this field I was fond of, not too far from here. It's been {sc}DESTROYED{/sc} since, do you know what happened?"
                        
                        "Faculty Member" "Ah. Apologies but I don't think I've heard about that."
                        
                        yuuka "I see."
                        
                        "Faculty Member" "What a shame... I think I've seen that same field."
                        
                        "Faculty Member" "When will we stop this shameless destruction?"
                        
                        yuuka "We? This school has done {sc}similar{/sc} things before?"
                        
                        "Faculty Member" "God, I hope not."
                        
                        "Faculty Member" "I'm just speaking in general, about all of humanity."
                        
                        "Faculty Member" "We've devastated the world enough, haven't we? Not that our leaders listen."
                        
                        yuuka "...no, they certainly don't. I'm glad to see you understand."
                        
                        yuuka "..."
                        
                        $ asked_field_faculty = True
                    
                    elif(not asked_office_location):

                        "Faculty Member" "Ah, looking for something?"

                        yuuka "I was just wondering where Professor Okazaki's teaching materials are, I was hoping to take a look at them."

                        yuuka "{i}And destroy it so I'd see the look on her face when she returns.{/i}"

                        "Faculty Member" "She didn't share it with you? Odd, but she has her own office."

                        "Faculty Member" "It's around the corner, behind a keypad. Did she tell you the passcode?"

                        yuuka "No, I believe I was too late to catch her before she left."

                        "Faculty Member" "Well that's a shame, for all she gushes about technology, her office, her phone, she's a difficult person to contact."

                        "Faculty Member" "You'd know her better than me, probably. It's a four-digit code, can't be that hard to guess right?"

                        yuuka "...sure."

                        yuuka "I have another concern actually."

                        $ asked_office_location = True
                    
                    yuuka "Professor Okazaki should be arriving in a few days, right?"
                    
                    "Faculty Member" "Well, that was the plan but you know how she can get."
                    
                    "Faculty Member" "Brilliant but impulsive. She's coming back tomorrow."
                    
                    yuuka "Tomorrow... that's sooner than I thought."
                    
                    yuuka "Good. That's less time until I get to face with her."
                    
                    "Faculty Member" "You're close with her?"
                    
                    yuuka "Ah, well, keep your friends close..."
                    
                    "Faculty Member" "?"

                    jump hallway_navigation3

                "Go to the auditorium" if did_not_visit_auditorium:
                    scene bg auditorium with fade

                    if "Clue #2" in inventory_items:
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation3

                    if skip_bulk_classroom:

                        yuuka "I found a student who's talking unnaturally like you said."

                        show marisa surprise with dissolve

                        marisa "What happened?"

                        jump show_marisa_the_student

                    else:
                        
                        yuuka "Huh, Marisa."
                        
                        show marisa neutral with dissolve
                        
                        marisa "That's the name."

                        yuuka "If you're here to gush about the school or about me or..."

                        show marisa laugh

                        marisa "Huh? No, I'm just chilling. You know they just have Outside World technology lying around here?"

                        yuuka "Don't steal it."

                        marisa "Haha, sure."

                        show marisa defiant

                        yuuka "{i}I saw her then pat her pockets, as if to smooth out any technology-shaped wrinkles.{/i}" (cb_name="")

                        yuuka "What's in the pockets?"

                        show marisa happy
                        
                        marisa "Nothin'. You figure out the buisiness with the destroyed field?"

                        yuuka "Deflecting, huh? Well, I already knew its Yumemi's fault from the get-go."

                        show marisa serious

                        marisa "Right. In any case, things have been off on my end."

                        marisa "Reimu and Alice haven't managed to dig up anything on their end either, though Reimu has been talking to some of the faculty about a suspicious lookin' janitor."

                        if("Keycard" in inventory_items):
                            yuuka "I think I know them myself... if not by face."
                        else:
                            yuuka "I'm not sure I follow."

                        show marisa neutral

                        marisa "Eh don't worry too much about it. Reimu does what Reimu does best, and that's following her instincts."

                        show marisa serious

                        marisa "I've been asking the students myself but it's been weird."

                        marisa "There's a lot of repeated words, phrases, sentences. It's all a little unnatural. They're all normal humans as far as I can tell, of course. It's just... weird."

                        if did_not_visit_classroom:
                            yuuka "Well, I'm glad there's at least some effort on your ends."

                            show marisa laugh
                            
                            marisa "What you thought we were just here for the fun of going to school? Yuck!"

                            if(exam_cancelled == False):
                                marisa "Nice job on the new exam by the way. I still had to get creative with it but at least I knew the last question by heart."
                            else:
                                marisa "Nice job by the way with cancelling the exams."

                            yuuka "You're welcome."

                            show marisa concerned

                            marisa "\"You're welcome?\" The tiger does knows manners!"

                            yuuka "Careful, this one knows how to bite too."

                            marisa "I certainly won't say you're all paper. Fifty percent max: you're part parcel."

                            yuuka "Would you like to test that theory?"

                            show marisa neutral

                            marisa "Any day."

                            yuuka "Hmph. Well, you never stood out for your timidity."

                            show marisa laugh

                            marisa "What can I say? My heart's as big as my hat. The normal one, this little cap's tiny in comparison."

                            yuuka "I'll see you around, Marisa."

                            show marisa happy

                            marisa "I sure hope so."
                        else:
                            yuuka "I had a similar experience earlier, actually."

                            label show_marisa_the_student:

                                yuuka "How about I show you?"

                                show marisa happy

                                marisa "Hmm, show away then."

                                scene bg classroom with fade
                                
                                yuuka "Hey."
                                
                                "Excitable Student" "Oh! Good afternoon, Miss! Good afternoon, Marisa! I was just arranging the seats."

                                yuuka "You said that earlier didn't you?"

                                "Excitable Student" "I did? That's a funny coincidence."

                                marisa "She's not acting THAT weird compared to normal."

                                yuuka "Her eyes went glassy earlier after we talked for a bit. Let me try something."

                                yuuka "You're a real bundle of joy; even more than usual. Are you excited because the exam's over?"

                                "Excitable Student" "It's not that, though I'm happy to finally have some free time."

                                "Excitable Student" "It's just seems like everything's changed lately. It's so... exciting."

                                yuuka "There we go. Look at her eyes."

                                marisa "I'm looking."

                                "Excitable Student" "The world outside seems different somehow... like we've forgotten something for so long only for it to slip back in without us noticing."

                                "Excitable Student" "I wonder... when was the last time I saw the city?"

                                yuuka "Exactly what she said earlier."

                                marisa "I've got things to say. Let's move back, first."

                                "Excitable Student" "Thanks again, Miss!"

                                scene bg auditorium with fade

                                show marisa serious with dissolve

                                marisa "Yeah, I had the same thing happen while I was trying to chat with some of the students."

                                marisa "They all arrive to school in the morning and leave in the evening but where are they coming and going from?"

                                marisa "I tried tailing them but then I'd just blank out myself."

                                yuuka "This is deeply concerning."

                                marisa "I wonder... didn't I tell Reimu and Alice this too? Have they not brought it up with you?"

                                yuuka "No, never."

                                show marisa defiant

                                marisa "...this seems bad. I'm gonna go now, I'll see if I can track down Yumemi right now."

                                marisa "I've got a feeling this is full-blown incident."

                                show marisa serious

                                marisa "You know Yumemi's office right?"

                                if asked_office_location:
                                    yuuka "Yes."
                                else:
                                    yuuka "I've not seen it, no."

                                    marisa "Ask around, the teachers would know."

                                show marisa happy

                                marisa "You should try and open the door."

                                marisa "Don't bother brute-forcing it by the way. Yumemi's stupid good with building things."

                                yuuka "I'm sure I could put a hole in it."

                                show marisa defiant

                                marisa "Nuh uh. And if you could, she'd probably put something dumb inside anyway to screw you and us over."

                                show marisa happy

                                marisa "She loves to play games, so play along for now."

                                yuuka "And how, pray tell, am I getting past her lock?"

                                show marisa neutral

                                marisa "It's four-digit keycode. It's probably something to do with a date or if she's trying to act clever, which is her default mode, then it's a date and something else."

                                show marisa serious

                                marisa "A birthday probably? Birth month, birth year? Could be anything, would have to narrow it from there."

                                marisa "Just keep that in mind. Probably a date and something else."

                                yuuka "In that order?"

                                marisa "Doesn't have to be, but probably. It's an easy order to stick in your head: significant date then something less obvious."

                                yuuka "Alright. Thank you, Marisa."

                                show marisa laugh

                                marisa "No problem, see ya teach."

                                show screen inventory_display_toggle
                                $ renpy.notify("Clue #2 gotten.")
                                $ inventory_items.append("Clue #2")
                                
                                $ marisaClue = True

                    $ marisa_progress += 1 # doubling the increment with going back here is probably fine
                    $ did_not_visit_auditorium = False
                    
                    jump hallway_navigation3

                "Go to her classroom" if did_not_visit_classroom:
                    scene bg classroom with fade
                    
                    # the one enthusiastic student who you couldve attacked at the start
                    
                    yuuka "Hm."
                    
                    "Excitable Student" "Oh! Good afternoon, Miss! I was just arranging the seats."
                    
                    yuuka "Good afternoon."
                    
                    yuuka "Hard working aren't you?"
                    
                    "Excitable Student" "I try, Miss."

                    "Excitable Student" "I must say, while it's not our subject I'm finding your lectures to be really intriguing."

                    if attacked_student:

                        "Excitable Student" "Tell me, what were the principles behind that gigantic flower you created?"

                    else:
                        
                        "Excitable Student" "Was there a reason for the sudden switch? From physics to botany that is."

                    yuuka "Don't ask, I-"
                    
                    yuuka "{i}A sullen pitiful expression turnt on her face and her feet stamped like an overanxious jackrabbit.{/i}" (cb_name="")

                    if attacked_student:

                        yuuka "...I can go in-depth if you'd want me to. Not now but, I think I can make time after Professor Okazaki is back."

                    else:
                        
                        yuuka "...I think I can make time to explain my reasons after Professor Okazaki is back."

                    "Excitable Student" "Really!? That'd mean the world to me!"

                    yuuka "{i}In her excitement, the student knocked over a chair.{/i}" (cb_name="")

                    "Excitable Student" "...oops."

                    yuuka "You're a real bundle of nerv- joy."

                    yuuka "A bundle of joy; even more than usual. Are you excited because the exam's over?"

                    "Excitable Student" "It's not that, though I'm happy to finally have some free time."

                    "Excitable Student" "It's just seems like everything's changed lately. It's so... exciting."

                    yuuka "{i}She took on a glassy-eyed expression after that.{/i}" (cb_name="")

                    "Excitable Student" "The world outside seems different somehow... like we've forgotten something for so long only for it to slip back in without us noticing."

                    "Excitable Student" "I wonder... when was the last time I saw the city?"

                    yuuka "Where do you go after school is over anyway? The village?"

                    "Excitable Student" "Huh? What are you talking about, Miss?"

                    "Excitable Student" "I'm just glad to have made it... when did I enter this school-{nw}"

                    "Excitable Student" "I'm just glad to have made it{fast} past that exam!"

                    yuuka "{i}And that expression disappeared into her cheerful self.{/i}" (cb_name="")

                    yuuka "R-right."
                    
                    yuuka "I'll be going now. Take care of yourself."

                    "Excitable Student" "Right! Thanks again, Miss!"

                    if not did_not_visit_auditorium:

                        yuuka "Didn't Marisa say something about unnatural conversations?"

                        $ did_not_visit_auditorium = True
                        $ skip_bulk_classroom = True

                    $ did_not_visit_classroom = False
                    
                    jump hallway_navigation3

                "Wait here" if janitor_talks < 3:

                    $ janitor_talks = 3

                    if("Keycard" in inventory_items):
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation3

                    if(has_correct_passcode):

                        show yumemi disguise with dissolve

                        janitor "Hey youngster."

                        janitor "Looks like you've been workin' hard huh? Or hardly workin'?"

                        yuuka "Har, har."

                        show screen inventory_display_toggle
                        $ renpy.notify("Keycard gotten.")
                        $ inventory_items.append("Keycard")

                        janitor "Anyhow, here ya go."

                        hide yumemi with dissolve

                        yuuka "?"

                        yuuka "Hold on, this is!"

                        yuuka "Wait, where'd she go?"

                    else:

                        janitor "So it's over, aye?"

                        show yumemi disguise with dissolve

                        yuuka "You enjoy soliciting conversations from strangers, much?"

                        yuuka "{i}In my attempt to ignore this person, I kept my eyes closed.{/i}" (cb_name="")

                        janitor "Only the pretty ones."

                        janitor "Ah, that's harassment ain't it? Professor Okazak's gonna have my head."

                        yuuka "..."

                        janitor "Don't tell, nobody, yea?"

                        hide yumemi with dissolve

                        yuuka "Irritance."

                    jump hallway_navigation3
                "Go to Yumemi's office" if did_not_submit_passcode and asked_office_location:

                    scene bg hallway at flip with fade

                    if(time_traveling):
                        yuuka "Here we are again."
                        yuuka "I better pick carefully."
                    else:
                        yuuka "Here we are."
                        yuuka "Gotta say, it looks like any other door I've seen. Except for the keypad that is."

                    menu:
                        "Does Yuuka enter a passcode?"

                        "Yes.":
                            $ passcode_attempt = renpy.input("ENTER FOUR DIGIT PASSCODE", allow="0123456789", length=4)
                            if(passcode_attempt == "0110"):
                                $ has_correct_passcode = True
                                yuuka "And ...it hasn't locked out on me yet."
                                "SCAN KEYCARD TO COMPLETE ENTRY"
                                if("Keycard" in inventory_items):
                                    yuuka "Scan it... how do you make this dreadful thing work?"

                                    yuuka "Uh huh, uh, okay. There we go."

                                    "KEYCARD CORRECT"

                                    "WELCOME PROFESSOR OKAZAKI"

                                    scene bg black

                                    yuuka "{i}Now I won't spoil exactly what I saw in that office but I will say.{/i}" (cb_name="")

                                    yuuka "{i}In addition to finding the exam data, stored in some kind of machinery that I deigned not to try to understand,{/i}" (cb_name="")

                                    yuuka "{i}Which is to say that I smashed it to little metal bits with great delight.{/i}" (cb_name="")

                                    yuuka "{i}There was also an intriguing absence of any time machine device, save for an opened safe that looked like it could've stored the device I hold now.{/i}" (cb_name="")

                                    yuuka "{i}Now, I'm not one for paradoxes...{/i}" (cb_name="")

                                    yuuka "{i}...{/i}" (cb_name="")

                                    yuuka "{i}And that's all I have to say on that subject.{/i}" (cb_name="")

                                    jump finale
                                else:
                                    yuuka "A keycard!? You mean I've been working my ass off to just get another lock?"

                                    yuuka "Fuck this. I'm out."
                            else:
                                if(time_traveling):
                                    yuuka "And... crap."
                                    yuuka "Wrong again."
                                else:
                                    yuuka "And that should be... wrong. Great."
                                    yuuka "Oh, and would you look at that, it's locked me out. Wonderful."
                                    yuuka "Damn it, that might've been my only try at this."
                                    yuuka "Fine then, maybe I ought to pivot to focusing on Yumemi herself instead of bothering with what she owns."
                                    yuuka "...or I could bust this door down."
                                    yuuka "Nah, saying it out loud makes it obvious that's just asking for people to turn on me. I'll find another approach to this."

                        "No, not yet.":
                            jump hallway_navigation
    elif day == 4:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N

        $ did_not_visit_faculty = True

        $ did_not_visit_auditorium = True

        $ did_not_visit_classroom = True

        yuuka "I shouldn't be able to be here, should I."

        yuuka "Not normally at least."

        label hallway_navigation4:
            
            scene bg hallway with fade

            # TODO: Have Yuuka recount what happened in these places before.
            
            menu:
                "Where does Yuuka go?"

                "{sc}Exit school{/sc}":
                    ""
                    # TODO: Put in the binary clue if you have gathered enough other clues (at least two)
                    jump day_transition

                "Go to the faculty room" if did_not_visit_faculty:
                    scene bg faculty with fade
                    
                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"

                    yuuka "It's so quiet..."

                    $ did_not_visit_faculty = False

                    jump hallway_navigation4

                "Go to the auditorium" if did_not_visit_auditorium:

                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"

                    yuuka "Surely, someone must've stayed behind somewhere in this school?"

                    yuuka "Surely..."

                    $ did_not_visit_auditorium = False
                    jump hallway_navigation4

                "Go to her classroom" if did_not_visit_classroom:
                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"
                    "{cps=1}...{/cps}"

                    yuuka "Empty."

                    $ did_not_visit_classroom = False
                    jump hallway_navigation4

                "Wait here" if janitor_talks < 4:

                    $ janitor_talks = 4

                    if("Keycard" in inventory_items):
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        jump hallway_navigation4

                    if(has_correct_passcode):

                        show yumemi disguise with dissolve

                        janitor "Hey youngster."

                        janitor "Looks like you've been workin' hard huh? Or hardly workin'?"

                        yuuka "Har, har."

                        show screen inventory_display_toggle
                        $ renpy.notify("Keycard gotten.")
                        $ inventory_items.append("Keycard")

                        janitor "Anyhow, here ya go."

                        hide yumemi with dissolve

                        yuuka "?"

                        yuuka "Hold on, this is!"

                        yuuka "Wait, where'd she go?"
                    else:
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"
                        "{cps=1}...{/cps}"

                    jump hallway_navigation4

                "Go to Yumemi's office" if did_not_submit_passcode and asked_office_location:

                    scene bg hallway at flip with fade

                    if(time_traveling):
                        yuuka "Here we are again."
                        yuuka "I better pick carefully."
                    else:
                        yuuka "Here we are."
                        yuuka "Gotta say, it looks like any other door I've seen. Except for the keypad that is."

                    menu:
                        "Does Yuuka enter a passcode?"

                        "Yes.":
                            $ passcode_attempt = renpy.input("ENTER FOUR DIGIT PASSCODE", allow="0123456789", length=4)
                            if(passcode_attempt == "0110"):
                                $ has_correct_passcode = True
                                yuuka "And ...it hasn't locked out on me yet."
                                "SCAN KEYCARD TO COMPLETE ENTRY"
                                if("Keycard" in inventory_items):
                                    yuuka "Scan it... how do you make this dreadful thing work?"

                                    yuuka "Uh huh, uh, okay. There we go."

                                    "KEYCARD CORRECT"

                                    "WELCOME PROFESSOR OKAZAKI"

                                    scene bg black

                                    yuuka "{i}Now I won't spoil exactly what I saw in that office but I will say.{/i}" (cb_name="")

                                    yuuka "{i}In addition to finding the exam data, stored in some kind of machinery that I deigned not to try to understand,{/i}" (cb_name="")

                                    yuuka "{i}Which is to say that I smashed it to little metal bits with great delight.{/i}" (cb_name="")

                                    yuuka "{i}There was also an intriguing absence of any time machine device, save for an opened safe that looked like it could've stored the device I hold now.{/i}" (cb_name="")

                                    yuuka "{i}Now, I'm not one for paradoxes...{/i}" (cb_name="")

                                    yuuka "{i}...{/i}" (cb_name="")

                                    yuuka "{i}And that's all I have to say on that subject.{/i}" (cb_name="")

                                    jump finale
                                else:
                                    yuuka "A keycard!? You mean I've been working my ass off to just get another lock?"

                                    yuuka "Fuck this. I'm out."
                            else:
                                if(time_traveling):
                                    yuuka "And... crap."
                                    yuuka "Wrong again."
                                else:
                                    yuuka "And that should be... wrong. Great."
                                    yuuka "Oh, and would you look at that, it's locked me out. Wonderful."
                                    yuuka "Damn it, that might've been my only try at this."
                                    yuuka "Fine then, maybe I ought to pivot to focusing on Yumemi herself instead of bothering with what she owns."
                                    yuuka "...or I could bust this door down."
                                    yuuka "Nah, saying it out loud makes it obvious that's just asking for people to turn on me. I'll find another approach to this."

                        "No, not yet.":
                            jump hallway_navigation4

label faculty:
    if day == 2:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N

        yuuka "{i}Next few days, actually.{/i}" (cb_name="")

        yuuka "{i}But I spent those days doing the same thing.{/i}" (cb_name="")

        yuuka "{i}Teaching.{/i}" (cb_name="")

        yuuka "{i}I learnt that this wasn't necessarily a normal school with my time here.{/i}" (cb_name="")

        yuuka "{i}Well normal as far as circumstances could allow.{/i}" (cb_name="")

        yuuka "{i}It was specifically a school merging Outside World education with magic.{/i}" (cb_name="")

        yuuka "{i}Now, I've no experience with the former but when it comes to magic, I think of myself as being above average.{/i}" (cb_name="")

        yuuka "{i}Things did get tense from time to time.{/i}" (cb_name="")

        # cutaway

        yuuka "Are you just dense or did your mother replace your brain with wool?"

        # cutback

        yuuka "{i}Yeah.{/i}" (cb_name="")

        yuuka "{i}The students kept attending, for the most part, which was a surprise.{/i}" (cb_name="")

        yuuka "{i}Professor Okazaki was apparently equally eccentric as I was.{/i}" (cb_name="")

        yuuka "{i}Part of what convinced people I was the real substitute.{/i}" (cb_name="")

        yuuka "{i}Which only made it more odd that the real one never showed up, if there ever was one.{/i}" (cb_name="")

        label additional_lecture:
            # added to flesh out her teaching more and actually see the classroom setting

            yuuka "The care of flowers should not only be to ensure their appearance, but to ensure they are fulfilled."

            yuuka "To prolong the life, to let it bloom and thrive, to not..."

            yuuka "..."

            yuuka "To not allow harm to come to it."

            if investigation_progress >= 2:
                yuuka "{i}I had gotten some leads into the destruction of the field that precipitated my arrival here.{/i}" (cb_name="")
                yuuka "{i}However, I had found just as many dead ends. Things didn't add up.{/i}" (cb_name="")
                yuuka "{i}I don't think I could've seen it coming, but I made my decision all the same.{/i}" (cb_name="")
            elif investigation_progress == 1:
                yuuka "{i}I had only begun investigating the destruction of the field that precipatated my arrival here.{/i}" (cb_name="")
                yuuka "{i}I should've set aside more time for that. I couldn't have known either way...{/i}" (cb_name="")
                yuuka "{i}But it never hurts to be prepared.{/i}" (cb_name="")
            else:
                yuuka "{i}I had neglected to look into the the destruction of the field that precipatated my arrival here.{/i}" (cb_name="")
                yuuka "{i}And for what reason should I have? It was obvious who was at fault.{/i}" (cb_name="")
                yuuka "{i}Perhaps, I should've looked into it.{/i}" (cb_name="")

            yuuka "Any questions class?"

            narrator "A few hands went up, too many to get to all of them in the time left, though notably one of the hands belonged to Reimu, another to Marisa."

            menu:
                "Who does Yuuka answer a question from?"

                "One of the normal students":
                    $ alice_progress += 1
                    yuuka "Yes?"
                    "Excitable Student" "I've heard that flower arranging focuses on having the flowers mirror the sun, moon, and earth."
                    
                    yuuka "Not really, a question but yes. It's not something I've ever used."
                    
                    yuuka "What each flower says shouldn't be limited to how we interpret it. A single petal stretches farther than the ocean beyond."

                    narrator "Another hand went up."

                    yuuka "Yes?"

                    alice "What other than interpretation do we have then?"

                    yuuka "I'm glad you asked, let me bring our conversation back to the language of flowers..."

                "Reimu":
                    $ chose_reimu_question = True
                    $ reimu_progress += 1
                    yuuka "Yes. Ms. Hakurei?"
                    reimu "Would you say that what we're doing, trying to connect with the flowers, is like what, say, a priest does with a god?"

                    yuuka "Mhm, while I wouldn't say it's the exact same, there are definite parallels."

                    reimu "What about gods of nature, of seasons, of... flowers? Is what we're doing talking to the flowers or to the god that might represent them?"

                    yuuka "That's a matter of demarcation. I've made up my mind on this, but let me walk you through the reasoning..."

                "Marisa":
                    $ marisa_progress += 1
                    yuuka "Yes, Ms. Kirisame?"

                    marisa "So when I'm picking out flowers from the forest paths..."

                    yuuka "That's a bad thing, yes, if that was your question."

                    marisa "But what if I using them to make something good, like medicine?"

                    yuuka "Like a disasterous alchemical explosion?"

                    marisa "Or that."

                    yuuka "Well... if a flower is nearing the end of its lifespan then that would be the time to consider such things."

                    yuuka "But we have to be able to tell the difference between a flower whose care has been neglected and one coming to its natural end. The first will..."

        yuuka "{i}Soon however, exams would come.{/i}" (cb_name="")

        yuuka "{i}Now I'm talking about midterms, right?{/i}" (cb_name="")

        yuuka "{i}No, it's not as dramatic a climax as final exams.{/i}" (cb_name="")

        yuuka "{i}But who would allow an untrained substitute that late into the semester to dictate the class?{/i}" (cb_name="")

        yuuka "{i}Especially one who has no idea what they're learning or even what subject she's taking over for.{/i}" (cb_name="")

        yuuka "{i}That's why it would've have made sense if it were midterms, but unfortunately Professor Okazaki is, again, very eccentric.{/i}" (cb_name="")

        yuuka "{i}The FINAL exams would come soon.{/i}" (cb_name="")

        # faculty room

        scene bg faculty

        if attacked_student:
            "Excitable Student" "Please, you've got to tell me how you did that giant sunflower!"
            
            "Excitable Student" "I'd kill to know how, it'd impress so much!"

            yuuka "{i}The final exams were to be a presentation of your best magic. Whether it be the most perfected, most flashy, most personal, most elegant.{/i}" (cb_name="")

            yuuka "{b}Kill{/b}, you say?"

            "Excitable Student" "That's right! So you see, I'm trying to get a good score in the Mass section of our rubric, based on last year's finals. As far as I can tell your magic is the most massive I've seen so far! Bar, Professor Okazaki's masterstroke, of course. On that, have you communicated with her? Are we still using last year's rubric or-{nw}"
        else:
            yuuka "{i}The final exams were to be a presentation of your best magic. Whether it be the most perfected, most flashy, most personal, most elegant.{/i}" (cb_name="")

            yuuka "You say you wanted to ask me something?"

            "Excitable Student" "That's right! So about our final exam, I was wondering about the rubric if we're following last year's system or if you'll be using your own? In which case, I'd like to ask what criteria are you using, are taking into account the student's participation in class because Professor Okazaki will attest that I-{nw}"

        yuuka "Please... just stop talking."

        "Excitable Student" "Okay.{w=1.0} Now what?"

        yuuka "Now what, what?"

        "Excitable Student" "Now what do you want me to do? If it means a good grade, I'll do anything!"

        yuuka "Well first, off you're still talking and, uh, second..."

        yuuka "...I'll need you to turn around, face the door."

        "Excitable Student" "Sure, done."

        yuuka "Then walk outside and leave. Come back tomorrow."

        "Excitable Student" "Got it! I'll do my best!"

        yuuka "And that's why you're my favorite student."

        yuuka "{i}She left soon after.{/i}" (cb_name="")

        "Faculty Member" "Having trouble with the kids, Miss... I still don't believe I've gotten your name?"

        yuuka "No, you haven't gotten it. And yes, I didn't expect consultations. I'd have thought the buggers, given how happy they are when class ends, wouldn't want more."

        "Faculty Member" "Well, I'm sure they feel they need any advantage they can get this late into the semester."

        "Faculty Member" "Has taking over Professor Okazaki's Magi-Physics class caused any issues?"

        yuuka "Magi-what?{nw}"

        yuuka "I mean, no, absolutely {sc}no{/sc} issues."

        yuuka "{i}I soon realized an issue.{/i}" (cb_name="")

        scene bg classroom with fade

        yuuka "Class, given your final exam is literally in two days, I've come to a decision."

        menu:

            "What does Yuuka propose?"

            "Revolution, obviously":

                $ revolution += 1

                yuuka "We are going to walk out on the upcoming exam. There will be no exam, so long as there are no teachers or students to take it."

                "Various Students" "No exam? Let's gooooooooooooooooooooooooooooooooooo{nw}"
                "Various Students" "But how will this affect the economy?{nw=1}"
                "Various Students" "Who cares about the economy? Anarchy!{nw=1}"
                "Various Students" "That's not what anarchy means. It literally means order without r{nw}"
                "Various Students" "I am begging you all to shut up.{nw=1}"
                "Various Students" "The teachers are in on this? Who exactly are we protesting then?{nw=1}"
                "Various Students" "The principal, I guess. Do we have a principal?{nw=1}"
                "Various Students" "I'd assume Professor Okazaki, isn't she the founder?{nw=1}"
                "Various Students" "Yeah, but she was fired.{nw=1}"
                "Various Students" "Huh, what's happening? Is it a test?{nw=1}"
                "Various Students" "Dude, you ask that every time we have class. Stop staying up, playing League of{nw}"
                "Various Students" "Dude, you ask that every time we have class. Stop staying up, playing {fast}Outlasting Maroon{nw=1.0}"

                yuuka "Are we clear on this?"

                "Various Students" "No!{nw=0.5}"

                yuuka "Good."

                alice "This is a terrible decision, Yuuka. Have you thought this out at all? You could tip Yumemi off that something's wrong."

                marisa "Worse than that, this means no Libraonmics class at two-thirty!"

                reimu "I thought you hated that class? You've never attended it."

                marisa "Yes, but the timeslot is perfect since it's taught by the school's main librarian."

                marisa "I'm in and out before the replacement can arrive. It's a way easier target than the Scarlets'"

                alice "Could we bring this back to the topic at hand? You're creating chaos, the students are out of control!"
                
            "Students teach students":

                yuuka "Class, I'll be opening up student tutoring regarding Magi-Physics."
                
                "Various Students" "It was weird we suddenly started doing Magi-Botany.{nw=1}"
                "Various Students" "I took it in stride, this is easy shit in comparison.{nw=1}"
                "Various Students" "We changed teachers?{nw=1}"
                "Various Students" "How have you just now noticed? Professor Okazaki is bright red from hair to clothes, you'd have to be blind to confuse her and... uh, I know this... it was...{nw=1}"
                "Various Students" "To be fair, I thought she could've just dyed her hair.{nw=1}"

                yuuka "Are we clear on this?"

                narrator "{i}A familiar hand went up.{/i}"

                yuuka "Yes?"

                "Student" "May I volunteer my friend, my inspiration, Ga{nw}"

                "A Different Student" "You backstabber! You should be tutoring, you actually like this class!{nw=1.0}"

                "Student" "Right, because you only like Professor Okazaki and her strawberry red hair, and her cape, so cool, and{nw}"

                "Once Again, A Different Student" "Can it, you two! The only person who should be handling other students is someone with experience. That's why I think Li{nw}"

                "Another Student Entirely, This Time" "You skunk! I taught you one time!{nw=1.0}"

                yuuka "Wow, I've really imparted my values onto this class haven't I."

                alice "That, for better or worse, you have."

                marisa "Worse. Definitely worse."

        reimu "Eh. It's about the same as how they'd react in the school in the Human Village."

        alice "But those are kindergarteners?"

        reimu "Exactly."

        narrator "{i}Reimu pointed at the class, arguments in various small pockets melding into a cacophony of voices.{/i}"

        reimu "Kindergarteners."

        yuuka "I'm glad you all see it my way~"

        marisa "Let's take this outside if we're actually going to talk. I'm getting a headache from listening to this."

        scene bg hallway with fade

        yuuka "So?"

        alice "What do you mean, \"so\"?"

        yuuka "Weren't you the one, Alice, that said I had to interact with humans more? I've been doing exactly that and see how it ended up."

        yuuka "Chaos and rage directed at one another: treating each other like how they treat the rest of nature's providence."

        yuuka "I simply let them be as they are."

        $ renpy.pause(1.0)

        alice "You know, what Yuuka?"

        alice "I'm not even going to argue with you."

        alice "You've determined you're right and that's all that matters to you."

        alice "Not the students, not me, and certainly most of all: not the flowers you seem to act like you're a representative for."

        yuuka "I quite literally am as a flower youkai."

        alice "No, I don't think you are. You just took it up as a face for yourself."

        alice "You don't seem to think of anything as different from playing with your food."

        alice "And frankly, I'm done trying to work with you. I'm going to be working around you from here on."

        yuuka "Is that a threat?"

        alice "It is the opposite of one. You're not my concern anymore."

        yuuka "Oh for your mother's sake, Alice. You know fully well what they've done, the thousands of lives beneath their feet, taken carelessly, thoughtlessly."

        marisa "Should we really be here?" # talking to reimu

        reimu "I say we stick to the sidelines for now."
        
        yuuka "You keep telling me to be mindful, to be considerate. Why, when so few will give the plants, give me that same chance?"

        yuuka "It's hypocrisy to demand of me so much when you don't speak the same way to those... children."

        alice "..."

        alice "I speak that way to you, Yuuka, because you are my friend."

        alice "But I don't know if you feel the same way."

        yuuka "..."

        alice "..."

        yuuka "What? Do you want me to give you some kind of bracelet?"

        alice "..."

        yuuka "{i}Alice sighed deeply then.{/i}" (cb_name="")

        yuuka "{i}To a degree I did, and still do, understand what she was getting at.{/i}" (cb_name="")

        yuuka "{i}Stubborn as we could both be.{/i}" (cb_name="")

        alice "It's not our problem if the students don't pass their class."

        reimu "Only if it turns into trouble for the rest of Gensokyo."

        marisa "And ya did kind of start a shouting match back there. That's noise disturbances at minimum."

        yuuka "Humans could do with being quiet a bit more often."

        reimu "Well, let's try and contain this before it erupts into something worse."

        if revolution != 0:

            yuuka "I was serious about there not being an exam."

            yuuka "I've seen their curriculum, it's all useless, extraneous topics."

            yuuka "Who would ever need to know how to file taxes when Gensokyo has no taxes?"

            alice "Agreed. If only they taught more important things like geography and linear algebra."

            marisa "Are we doing a bit? Who uses those things?"

            alice "Me."

            marisa "Why?"

            alice "For making my dolls and... making my dolls. They're all named after cities, did you never notice?"

            marisa "Well, you did name one of them Hourai."

            alice "That's a mountain. The elixir is named after the mountain."

            marisa "Ohhhhhhhhhh. Explains that, I thought it was just a funny name."

        else:

            yuuka "Would you all happen to be familiar with the Magi-physics that was previously taught?"

            marisa "Yeah, I know magic and I know physics."
            
            alice "Skilled as a practioner you are, you're hardly theoretician when it comes to magic, let alone physics, Marisa. Do you even know Netwon's three principles?"

            marisa "Drop a ball from a tower and it falls, shoot someone with a spellcard and they fall. Same thing right?"

            alice "That's Galileo."

            marisa "I thought Newton invented gravity?"

        yuuka "Do you actively try to be an idiot, Marisa?"

        marisa "I don't have to try; skills just come naturally to me."

        reimu "This is going nowhere."

        reimu "Yuuka, you're clearly more invested in these students' education that your attitude lets on."

        reimu "If you care about their exam, then do you have a plan? A next step?"

        yuuka "Yes, I just need to ensure certain people are convinced the exam is unnecessary or that they would rather not go at all."

        if revolution != 0:
            menu:
                "Who does Yuuka \"convince\"?"

                "The faculty":

                    # DONE
                    
                    $ revolution += 1
                    
                    yuuka "I'll talk with the actual teachers, see if I can't twist their arms into dropping this exam buisiness entirely."

                    alice "Okay. Don't actually twist their arms."

                    yuuka "It's just a figure of speech."

                    # cuts to yuuka twisting their arms

                    scene bg faculty

                    yuuka "And repeat it back to me, slowly."

                    "Faculty Member" "Yes, yes! No exams, I get it! Now {sc}LET GO{/sc}!"

                    scene bg classroom

                    yuuka "I glad to report to you all that the other teachers and I have come to a consensus regarding your exams. There will be no final exams."

                    "Student" "I'm happy we have a substitute who's so forgiving, huh Alice?"

                    alice "Right, forgiving."
                "The students":
                    
                    yuuka "Thinking about it, I don't even need to talk to the teachers do I?"

                    yuuka "So long as there are no students, there's no one to fail."

                    alice "Then they'll just fail everyone."

                    yuuka "Does it mean anything at that point?"

                    alice "Well... yes. They'd held back a year."

                    yuuka "But so would everyone else."

                    marisa "And so nothing would change! Not a bad idea!"

                    alice "They'd still have to repeat a year?"

                    yuuka "We could use the same tactic to stop them from repeating a year."

                    reimu "That might actually work..."

                    alice "This all seems terribly planned out."

                    yuuka "Stick in a mud as usual, Alice. Don't worry, I'll handle everything."
        else:
            yuuka "I said what I said. The students are just going to have to teach each other."

            yuuka "Besides didn't they have an entire semester to learn this, surely they know something about the topic they've taken up thus far."

            yuuka "Students wouldn't be unprepared for an upcoming exam, would they?"

            alice "No, surely not. They also would not procrastinate on their studies even if under a subsitute teacher."

            yuuka "I'm glad we've got our thumbs to the beating heart of the students, Alice. Knowing that, it's probably best to assign them to each other than leave them to their own devices."

            marisa "I am deeply uncomfortable with you saying you're holding the students' beating heart."

            reimu "I got chills from that image."

        scene bg black with fade

        # then determine if the teachers quit or not, and if not do the exams still happen?

        if revolution > 0:
            $ exam_cancelled = True
        
        if exam_cancelled:
            yuuka "{i}As you all know, the exams were to be called off the next day.{/i}" (cb_name="")
        
            if revolution >= 2:
                yuuka "{i}Not just that, but the faculty of the school went on a walk out, in protest of what they called my \"heavy-handed approach\".{/i}" (cb_name="")

                yuuka "{i}I became very popular with the students however.{/i}" (cb_name="")

                yuuka "{i}That's why as you're sitting in your seats, waiting for Professor Okazaki to sweep in and replace me, the menace you welcomed in,{/i}" (cb_name="")
                
                yuuka "{i}Just know that she won't be making it.{/i}" (cb_name="")
                
                yuuka "{i}I do hope I've made my distate of her clear by now?{/i}" (cb_name="")

                narrator "{i}One or two nervous nods came in response.{/i}"

                yuuka "{i}Yes? Good.{/i}" (cb_name="")

                yuuka "{i}Then I'll let you imagine how I dealt with her.{/i}" (cb_name="")

                yuuka "{i}I hope you intend to complete your walk out by quitting, now, dearies.{/i}" (cb_name="")

                yuuka "{i}This is my school and my students from here on out.{/i}" (cb_name="")

                if very_loud_quitting.has():
                    "Very Loud Quitting already has been completed. Consider finding a different ending."

                    $ very_loud_quitting.grant()

                    jump ending
            else:
                yuuka "{i}The students were estatic but the faculty were deeply worried.{/i}" (cb_name="")

                yuuka "{i}Worry no longer, for you now know the truth.{/i}" (cb_name="")

                yuuka "{i}Though it can never free you, at least you know.{/i}" (cb_name="")

                yuuka "{i}I ask not for sympathy. Just an understanding.{/i}" (cb_name="")

            jump hallway
        else:
            yuuka "{i}The students took to it well.{/i}" (cb_name="")

            yuuka "{i}We were correct that they had been prepared throughout the semester.{/i}" (cb_name="")

            yuuka "{i}And by that we mean they crammed like their lives depended on it.{/i}" (cb_name="")

            yuuka "{i}A sentiment that must be familiar to you all.{/i}" (cb_name="")

            yuuka "{i}The day fast approached and I had my own preparations to do...{/i}" (cb_name="")

            yuuka "{i}Seeing them work hard (with the addition of an extreme pressure) meant I felt a bit generous.{/i}" (cb_name="")

            yuuka "{i}It took a little bit of convincing but let me allow the results to speak for themselves in a moment.{/i}" (cb_name="")

            jump hallway

    # current plans: after consultations determines if there'll be a final exam at all

    elif day == 3:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N
        window show # placeholder
        return
    elif day == 4:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N
        window show # placeholder
        return
    else:
        "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
        return

label exam:
    if day == 3:
        # TODO
        # TEXT  Y
        # STAGE N
        # VAR   Y

        # This leads to the 7th ending
        if exam_cancelled:
            $ day += 1
            jump finale

        label exam_proper:
            scene bg classroom with fade
            # exam minigame thingy not really but based on the koakuma kiss comic making
            # keep it simple, draw a form

            # ----------------------------------- #
            # Student's perspective
            # slowly realizing that yuuka changed some questions to the exam

            "Student" "Hey, Reimu!"

            reimu "Huh, uh, yeah?"

            reimu "{i}Damn, I've been getting way to used to being a student.{/i}"

            "Student" "Did you review Professor Okazaki's research into the soul? I'm still confused by it, I was hoping you understood it better than I did."

            reimu "Oh, you could explain what you know then, to make sure we're on the same page."

            reimu "{i}And so I'll know what on earth you're going on about.{/i}"

            "Student" "Sure!"

            "Student" "So the force of a magical attack is its mass measured in the weight of a soul times acceleration."

            "Student" "That means we can derive the weight of a soul if we divide the force of a magical attack by its acceleration."

            "Student" "Now, we need a way to measure the force of a-"

            yuuka "Take your seats and put away anything that isn't a pen."

            "Student" "Oh, uh, you measure it with a ballistic p-"

            # something in between

            # F = m × a becomes m = F/a

            # reimu takes the exams

            "What is the formula for the mass of a magical attack?"

            show text "A. m = F / a\nB. m = a x m\nC. m = a / F\nD. m = F x m" at truecenter

            if(persistent.playeranswer1 == ""):

                $ msg = renpy.input("What is the formula for the mass of a magical attack?")

                $ persistent.playeranswer1 = msg
                $ renpy.save_persistent()

                hide text

                reimu "{i}I hope I got that right...{/i}"
            else:
                reimu "{i}It's [persistent.playeranswer1] right?{/i}"

            # 

            "With what device do you measure the force of a magical attack?"

            show text "A. Ballistic Perforator\nB. Ballistic Pendulum\nC. Ballast\nD. Ballistic Shell" at truecenter

            if(persistent.playeranswer2 == ""):

                $ msg = renpy.input("With what device do you measure the force of a magical attack?")

                $ persistent.playeranswer2 = msg
                $ renpy.save_persistent()
                
                hide text

                reimu "{i}I hope I got that right...{/i}"
            else:
                reimu "{i}It should be... [persistent.playeranswer2]. I think?{/i}"

            # 
            
            "What flower is well-known for turning to face the sun?"

            show text "A. Lotus Flower\nB. Hydrangea\nC. Rose\nD. Sunflower" at truecenter

            if(persistent.playeranswer3 == ""):

                $ msg = renpy.input("What flower is well-known for turning to face the sun?")
                $ persistent.playeranswer3 = msg
                $ renpy.save_persistent()
                
                hide text

                reimu "{i}That's a weird one but it seems pretty easy, no?{/i}"
            else:
                reimu "{i}That's a weird one but [persistent.playeranswer3], right? It seems easy compared to the others?{/i}"

            # 

            "What is the language of flowers?"

            show text "A. Written language on flower petals\nB. Poetic metaphors using flowers\nC. How flowers attract bees\nD. The voice the flowers speak in" at truecenter

            if(persistent.playeranswer4 == ""):

                $ msg = renpy.input("What is the language of flowers?")

                $ persistent.playeranswer4 = msg
                $ renpy.save_persistent()
                
                hide text

                reimu "{i}Hey wait a minute...{/i}"
            else:
                reimu "{i}[persistent.playeranswer4]. Hey wait a minute...{/i}"

            #

            "Who's gonna pass this exam?" 

            show text "A. You.\nB. Yes, you.\nC. Don't deny it.\nD. Isn't it obvious?" at truecenter

            if(persistent.playeranswer5 == ""):

                $ msg = renpy.input("Who's gonna pass this exam?")

                $ persistent.playeranswer5 = msg
                $ renpy.save_persistent()
                
                hide text

            reimu "{i}Did Yuuka change the exam questions?{/i}"
            reimu "{i}Huh, that's... really nice of her. If she keeps this up I'll have to ask Akyuu to change her profile in the Gensokyo Chronicle.{/i}"
            reimu "{i}Assuming this isn't just a plot of hers.{/i}"
            reimu "{i}...I hope it isn't. Besides, she's more of the brute force type anyway.{/i}"

            jump hallway
    else:
        "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
        return

label penultimate_presentation:
    if day == 4:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N
        
        "Test ending rewards"

        # ---------------- #
        if she_has_your_back.has():
            "She Has Your Back already has been completed. Consider finding a different ending."
        elif not dontsavefutureruns:
            $ persistent.officialrun = SaveChoices()
            $ persistent.dontsavefutureruns = True

        $ she_has_your_back.grant()
        # ---------------- #
        if they_have_your_back.has():
            "They Have Your Back already has been completed. Consider finding a different ending."
        elif not dontsavefutureruns:
            $ persistent.officialrun = SaveChoices()
            $ persistent.dontsavefutureruns = True

        $ they_have_your_back.grant()
        # ---------------- #
        if hedgehog_dilemma_solved.has():
            "Hedgehog's Dilemma Solved already has been completed. Consider finding a different ending."
        elif not dontsavefutureruns:
            $ persistent.officialrun = SaveChoices()
            $ persistent.dontsavefutureruns = True

        $ hedgehog_dilemma_solved.grant()
        # ---------------- #

        jump ending
    else:
        "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
        return

label finale:
    # the you finished enough of the game idgaf route

    # it should happen in the garden of the sun

    return

label day_transition:
    scene bg black with fade
    $ renpy.pause(1.0)
    python:
        if layout.yesno_prompt("none", "Do you want save your game?"):
            try:
                renpy.save("1-1", extra_info="auto-save")
                renpy.say("", "Game saved.")
            except:
                renpy.say("", "Save failed.")
                renpy.say("", "Proceeding without saving game.")
        else:
            renpy.say("", "Proceeding without saving game.")
    narrator "{i}The next day...{/i}"

    if("Clue #1" in inventory_items and "Clue #2" in inventory_items and "Clue #3" in inventory_items and not "Clue #4" in inventory_items):
        scene bg garden at flip with fade

        play music "wind_atmo.mp3" if_changed

        play sound "wind3.mp3"
        $ renpy.pause(6.0, hard=True)
        
        "01101101 01100101 01100100 01101001 01110101 01101101 00100000 01101001 01110011 00100000 01101101 01110011 01100111"

        show screen inventory_display_toggle
        $ renpy.notify("Clue #4 gotten.")
        $ inventory_items.append("Clue #4")
    elif("Clue #1" in inventory_items or "Clue #2" in inventory_items or "Clue #3" in inventory_items):
        scene bg garden at flip with fade

        play music "wind_atmo.mp3" if_changed

        play sound "wind2.mp3"
        $ renpy.pause(3.0, hard=True)
        
        "{cps=7}Getting... closer...{/cps}"

        "{cps=8}Return... three...{/cps}"
        
    scene bg garden with fade

    # sunflower talk
    if day == 1:

        play music "wind_atmo.mp3" if_changed
 
        play sound "wind1.mp3"
        $ renpy.pause(3.0, hard=True)

        show yuuka looking with dissolve

        yuuka "Good morning, my dears."

        play sound "wind2.mp3"
        $ renpy.pause(3.0)

        yuuka "Indeed, quite a terrible act was inflicted on your brethren."

        play sound "wind3.mp3"
        $ renpy.pause(3.0)

        yuuka "I have my plans. I do hope you eagerly await the fruits of my labor."

        stop music
    elif day == 2:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N

        play music "wind_atmo.mp3" if_changed

        play sound "wind1.mp3"
        $ renpy.pause(3.0, hard=True)

        show yuuka looking with dissolve

        yuuka "Good tidings, I believe I am planting seeds germinating in those miscreants."

        play sound "wind2.mp3"
        $ renpy.pause(3.0)

        yuuka "In time, I will turn even Yumemi's own students against her."

        play sound "wind3.mp3"
        $ renpy.pause(3.0)

        yuuka "I will take great pleasure in seeing her downfall, as well."

        stop music
    elif day == 3:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N

        play music "wind_atmo.mp3" if_changed

        play sound "wind1.mp3"
        $ renpy.pause(3.0, hard=True)

        show yuuka looking with dissolve

        yuuka "I'm sorry I haven't attended to you as much this past week. I've had other seedling taking up my time."

        play sound "wind2.mp3"
        $ renpy.pause(3.0)

        yuuka "I'm sorry. There's just one more thing I have to do after this. I hope you'll understand."

        play sound "wind3.mp3"
        $ renpy.pause(3.0)

        yuuka "...I really hope you'll understand."

        stop music
    elif day == 4:
        # TODO
        # TEXT  N
        # STAGE N
        # VAR   N
        # $ investigation_progress
        play music "wind_atmo.mp3" if_changed

        play sound "wind1.mp3"
        $ renpy.pause(3.0, hard=True)

        "..."

        play sound "wind2.mp3"
        $ renpy.pause(3.0)

        "..."

        play sound "wind3.mp3"
        $ renpy.pause(3.0)

        "..."

        stop music
        return
    else:
        "Day is currently set to [day]. This should be impossible. You've likely encountered a bug."
        return

    $ renpy.jump(next_label)

label ending:

    # $ long_term.grant()
    # $ scare_tactics.grant()
    # $ very_loud_quitting.grant()
    # $ she_has_your_back.grant()
    # $ they_have_your_back.grant()
    # $ hedgehog_dilemma_solved.grant()
    # $ retroactive.grant()

    # if long_term.has():
    #     "Long Term already has been completed. Consider finding a different ending."
    # if scare_tactics.has():
    #     "Scare Tactics already has been completed. Consider finding a different ending."
    # if very_loud_quitting.has():
    #     "Very Loud Quitting already has been completed. Consider finding a different ending."
    # if she_has_your_back.has():
    #     "She Has Your Back already has been completed. Consider finding a different ending."
    # if they_have_your_back.has():
    #     "They Have Your Back already has been completed. Consider finding a different ending."
    # if hedgehog_dilemma_solved.has():
    #     "Hedgehog Dilemma Solved already has been completed. Consider finding a different ending."
    # if retroactive.has():
    #     "Retroactive already has been completed. Consider finding a different ending."

    show screen ending_gallery

    jump pause_loop

    return

label pause_loop:

    window hide
    $ renpy.pause()

    jump pause_loop